Compter les lignes entre les «X»

Je veux compter les lignes entre "X". C'est juste un exemple; Je dois appliquer le code à un résultat biologique complexe. Je serai reconnaissant si vous pouvez suggérer une commande, de préférence en utilisant awk, grepou sedcomme je les connais.

Exemple:

X
Y
Y
Y
X
Y
Y
Y
Y
X
Y
X

Sortie désirée:

3
4
1

Avec awk:

$ awk '!/X/{count++}/X/{print count; count = 0}' input

3
4
1

Incrémentez un décompte pour chaque ligne ne contenant pas X; imprimer et réinitialiser le nombre de lignes contenant X.

$ awk '/X/ && prev{print NR-prev-1} /X/{prev=NR}' file
3
4
1

Comment ça fonctionne:

Awk lit implicitement les fichiers d'entrée ligne par ligne.

• /X/ && prev{print NR-prev-1}

  Pour toute ligne contenant Xet si nous avons précédemment attribué une valeur à prev, imprimez le numéro de la ligne actuelle NR, moins prevmoins un.

• /X/{prev=NR}

  Pour toute ligne qui contient X, définissez la variable prevau numéro de ligne en cours, NR.

Une autre awkapproche simple qui fonctionne sur les échantillons de données OP et si elle Xn'était pas dans le premier ou même dans les derniers X ou répétés.

awk -v RS='X' 'NF{print NF}' infile

Au- dessus est correct quand il n'y a qu'un seul champ dans chaque ligne par défaut FS toutes les espaces blancs , sinon ci - dessous est révisée en cas général pour le comptage linewise . Vous pouvez entrer votre MOTIF en place de X là.

awk -F'\n' -v RS='X' 'NF>2{print NF-2}'

Exemple d'entrée:

X
Y YYY Y
YY
YY Y YY YY Y Y
X
Y Y Y
X
Y
Y
X
X

La sortie est:

3
1
2

La plupart des réponses correspondent au contenu de la ligne à compter à l'aide d'expressions régulières intégrées au programme Awk. Si vous devez faire correspondre des lignes avec du contenu qui peut contenir des caractères spéciaux (soit pour Awk ou des expressions régulières), il serait préférable de comparer réellement les chaînes pour l'égalité. Par conséquent, je propose le script Awk suivant comme variante de la réponse de muru :

BEGIN {
    count = 0;
}

{
    if ($0 == needle) {
        if (count) {
            print count;
            count = 0;
        }
    } else {
        count++;
    }
}

Stockez-le sous forme de fichier texte, par exemple count-rows.awk, et invoquez-le comme suit:

awk -f count-rows.awk -v needle=X input

Vous pouvez ajuster la valeur de needleà votre guise. L'avantage de cette méthode est que vous pouvez appeler le programme à partir d'un script shell avec une valeur arbitraire pour needlesans échapper aux problèmes:

awk -f count-rows.awk -v needle="$needle" input