Comment écrire le script attendu pour installer mariadb?

Environnement: centos7 + mariadb5.5.64.
Permettez-moi de montrer les informations d'installation à l'écran quand exécuter mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

J'écris un script d'automatisation pour installer mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Pour exécuter /usr/bin/expect secure.exp, je tombe sur l'erreur:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Il est inutile d'écrire comme ci-dessous:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Même erreur:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Comment puis-je réparer mon script exp?

Ces scripts attendent de recevoir une sortie facultative ( timeout -1signifie «pas de délai d'attente») et ils peuvent distinguer les différentes réponses, comme requis par yum installet mysql_secure_installation. Avec #!/bin/expect -fas shebang, les scripts peuvent être exécutés, lorsqu'ils ont été définis sur chmod +x.

A) Pour commencer, mariadb_yum.exp(nécessite suou sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) Et puis mariadb_sec.exp(ne nécessite pas sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

À des fins de débogage - ou pour valider la réponse, on peut exécuter expectavec le niveau de journal strace 4. C'est probablement aussi fiable qu'une source peut obtenir, quand il s'agit d'écrire des expectscripts, car il affiche bien ce qui se passe et, surtout, dans quel ordre les choses se produisent:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

L'instruction set exp_internal 1peut être utilisée pour obtenir une sortie pour la correspondance d'expression régulière.

Une source possible de confusion pourrait être, où l'on engendre les processus - comme on peut engendrer plusieurs processus sur différents hôtes, par exemple. sshau niveau local, puis yumet à mysql_secure_installationdistance. Ajouté $spawn_idau script; le dernier closeappel peut être redondant, car il l'est déjà EOF(juste pour montrer comment spawnet closetraiter):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Conclusion: le mariadb_sec.expscript pourrait probablement être encore amélioré, par exemple. lors de l'envoi initial d'un mot de passe et de voir ce qui se passe - puis en envoyant le mot de passe ERROR 1045(lorsqu'un mot de passe avait déjà été défini précédemment). Il peut être prudent de supposer que l'on doit définir le mot de passe lorsque le serveur vient d'être installé (sauf qu'il yum reinstallfournit le même résultat). Je n'avais pas de conteneur CentOS vide pour tester tous les cas. À moins de s'exécuter dans un rootshell, il serait nécessaire de passer les deux types de mots de passe dans un seul script pour automatiser cela de l'installation jusqu'à la post-installation.

Il convient probablement de noter que sur GCE, sudone demanderait pas de mot de passe; il existe en effet des différences mineures en fonction de l'environnement, car ces images de conteneurs CentOS se comportent différemment. Dans ce cas (puisqu'il n'y a pas de sudétection d'image conteneur ou en place), le mariadb_yum.expscript peut rester bloqué pendant 30quelques secondes, puis continuer.

Les sources les plus réputées que je puisse offrir sont le expectmanuel, écrit par Don Libes @ NIST et le manuel TCL / TK pour expect, avec son projet SourceForge appelé par hasard expect.

Non seulement les crochets sont utilisés pour la substitution de commandes, mais ils sont également spéciaux pour les modèles glob .

Vous pouvez soit utiliser le -exactcommutateur tout en échappant aux crochets entre guillemets:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Ou utilisez des accolades au lieu de guillemets:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

Pour info, vous pouvez faire générer le script expect pour vous en utilisant autoexpect:

autoexpect ./mysql_secure_installation

Cela générera un script attendu appelé script.expdans votre répertoire de travail actuel.