Vous avez ajouté un bouton à votre DataGridViewet vous souhaitez exécuter du code lorsque l'utilisateur clique dessus.
Easy peasy - suivez simplement ces étapes:
À ne pas faire:
Tout d'abord, voici ce que PAS faut faire:
J'éviterais les suggestions dans certaines des autres réponses ici et même fournies par la documentation de MSDN pour coder en dur l'index de la colonne ou le nom de la colonne afin de déterminer si un bouton a été cliqué. L'événement de clic est enregistré pour l'ensemble de la grille, vous devez donc d'une manière ou d'une autre déterminer qu'un bouton a été cliqué, mais vous ne devriez pas le faire en supposant que votre bouton réside dans un nom de colonne ou un index particulier ... il existe un moyen plus simple ...
Faites également attention à l'événement que vous souhaitez gérer. Encore une fois, la documentation et de nombreux exemples se trompent. La plupart des exemples gèrent l' CellClickévénement qui se déclenchera:
lorsque l'utilisateur clique sur n'importe quelle partie d'une cellule.
... mais se déclenchera également chaque fois que l'en- tête de ligne est cliqué. Cela nécessite d'ajouter du code supplémentaire simplement pour déterminer si la e.RowIndexvaleur est inférieure à 0
Au lieu de cela, gérez ce CellContentClickqui se produit uniquement:
lorsque l'utilisateur clique sur le contenu d'une cellule
Pour une raison quelconque, l'en - tête de colonne est également considéré comme du «contenu» dans une cellule, nous devrons donc toujours vérifier cela ci-dessous.
Dos:
Alors, voici ce que vous devez faire:
Commencez par convertir l'expéditeur en saisieDataGridView pour exposer ses propriétés internes au moment du design. Vous pouvez modifier le type du paramètre, mais cela peut parfois rendre difficile l'ajout ou la suppression de gestionnaires.
Ensuite, pour voir si un bouton a été cliqué, vérifiez simplement que la colonne déclenchant l'événement est de type DataGridViewButtonColumn. Comme nous avons déjà converti l'expéditeur en type DataGridView, nous pouvons obtenir la Columnscollection et sélectionner la colonne actuelle à l'aide de e.ColumnIndex. Vérifiez ensuite si cet objet est de type DataGridViewButtonColumn.
Bien sûr, si vous avez besoin de faire la distinction entre plusieurs boutons par grille, vous pouvez ensuite sélectionner en fonction du nom de la colonne ou de l'index, mais cela ne devrait pas être votre première vérification. Assurez-vous toujours qu'un bouton a été cliqué en premier, puis gérez tout le reste de manière appropriée. Dans la plupart des cas où vous n'avez qu'un seul bouton par grille, vous pouvez passer directement aux courses.
Mettre tous ensemble:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Mise à jour 1 - Événement personnalisé
Si vous voulez vous amuser un peu, vous pouvez ajouter votre propre événement à déclencher chaque fois qu'un bouton est cliqué sur le DataGrid. Vous ne pouvez pas l'ajouter au DataGrid lui-même, sans être compliqué avec l'héritage, etc., mais vous pouvez ajouter un événement personnalisé à votre formulaire et le déclencher le cas échéant. C'est un peu plus de code, mais l'avantage est que vous avez séparé ce que vous voulez faire lorsqu'un bouton est cliqué avec la façon de déterminer si un bouton a été cliqué.
Déclarez simplement un événement, déclenchez-le si nécessaire et gérez-le. Il ressemblera à ceci:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Mise à jour 2 - Grille étendue
Ce qui serait génial, c'est que nous travaillions avec une grille qui ne faisait que cela pour nous. On pourrait facilement répondre à la question initiale: you've added a button to your DataGridView and you want to run some code when it's clicked. Voici une approche qui étend le DataGridView. Cela ne vaut peut-être pas la peine d'avoir à fournir un contrôle personnalisé avec chaque bibliothèque, mais au moins, il réutilise au maximum le code utilisé pour déterminer si un bouton a été cliqué.
Ajoutez simplement ceci à votre assemblage:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
C'est tout. Ne le touchez plus jamais. Assurez-vous que votre DataGrid est d'un type DataGridViewExtqui doit fonctionner exactement de la même manière qu'un DataGridView. Sauf que cela déclenchera également un événement supplémentaire que vous pouvez gérer comme ceci:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
