Aller à X octets d'ici

Comment déplacer X octets vers l'avant, à partir de l'emplacement actuel du curseur (y compris les sauts de ligne)?

[count]gopourrait être utilisé pour avancer X octets depuis le début du tampon. J'ai essayé Shift + V, G, [count]go(en supposant que [count]gocela commencerait à compter depuis le début de ma sélection), mais malheureusement cela n'a pas fonctionné non plus car il gone commence à compter qu'à partir du début de la mémoire tampon.

J'ai également essayé :set rulerformat=%od'afficher le décalage d'octet actuel (comme suggéré par le passage à un décalage d'octet et l'affichage de la position comme décalage d'octet ), j'ai ajouté les chiffres dans ma tête et finalement publié [count]go. Cela fonctionne, mais ce n'est pas très pratique ...

Cette recherche déplace 40 caractères (pas d'octets, cependant) vers l'avant:

/\_.\{40}/e

en recherchant exactement 40 caractères ( \{40}) de toute sorte, y compris newline ( \_.), et en plaçant le curseur à la fin de la recherche ( /e). Voir: http://vimregex.com/#Non-Greedy , :help search-offsetet:help \_

Voir également :h 23.4pour l'édition binaire.

Mise à jour: Sur la base de cette réponse, voici une fonction qui passe au décalage d'octet:

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

Peut être utilisé comme ceci:

:JumpToOffset 400

ou en tapant le mappage du clavier mappé, avec un nombre:

40CTRL-C

Si vous n'utilisez pas de comptage, le numéro de comptage précédent est réutilisé. Vous pouvez donc faire: 40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-Csauter 40, 40, 40, 30, 30 octets, etc.

Appuyez Ctrl-Opour sauter en arrière (voir les commentaires à l'intérieur de la fonction).

J'ai fini par utiliser la solution suivante, qui met en œuvre la logique de ma question.

• [count]GOpour avancer les [count]octets.
• [count]Gopour déplacer les [count]octets en arrière.

Ajoutez ceci à votre .vimrc:

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

Merci à VanLaser pour sa mise en œuvre initiale, qui m'a mis dans la bonne direction.