Est-il possible d'utiliser deux arrière-plans de couleurs différentes dans un seul tampon vim?

Je cherche une solution possible pour appliquer deux couleurs d'arrière-plan différentes à l'intérieur d'un seul tampon vim en fonction du contexte comme dans cet exemple de texte sublime .

Un cas d'utilisation de cela est de colorer les extraits de code à l'intérieur des fichiers de balisage différemment afin qu'ils se démarquent davantage.

Cependant, je n'ai jamais vu d'exemple avec une telle configuration.

Est-ce que cela est possible dans vim?

Parce que j'étais curieux de savoir comment cela fonctionnerait, j'ai piraté quelque chose ensemble ce genre de travaux.

Comme mentionné dans les commentaires sur la réponse précédente, la seule façon de le faire est de remplir les régions avec des espaces; c'est exactement ce que nous faisons; avant d'écrire, nous supprimons ces espaces, vous ne devriez donc pas déranger qui que ce soit d'autre.

Notez que cet exemple est très spécifique pour le type de fichier Markdown!

Effets secondaires :

• La copie de texte copiera également de nombreux espaces
• Utiliser $et Endne fonctionne plus comme prévu (il va à la colonne 80), et des clés telles que jet kse comportent également différemment.
• L'arrière-plan ne s'affiche pas lorsque 'list'est activé
• Les lignes complètement vides ne fonctionnent pas, vous devez ajouter manuellement une tabulation ou 4 espaces
• ... Peut-être plus?

Tout d'abord, vous devez l'ajouter à votre ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Vous pouvez bien sûr ajuster les couleurs à votre guise ;-)

Ensuite, ajoutez ceci à votre vimrc:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Je ne vais pas expliquer le code ligne par ligne, les commentaires devraient clarifier l'essentiel général ;-)

Il est certainement possible d'utiliser une couleur d'arrière-plan différente pour les éléments mis en évidence par la syntaxe. Définissez simplement les couleurs guibget ctermbgdans votre hilightcommande. Le premier définit la couleur d'arrière-plan pour GUI Vim, et le second pour le terminal Vim.

Cependant, cela présente l'importante limitation du fait qu'il ne peut définir que les couleurs d'arrière-plan des caractères qui existent réellement dans le fichier.

Le résultat est que la couleur d'arrière-plan ne peut pas s'étendre au-delà de la fin du texte sur une ligne jusqu'au bord de la fenêtre, de sorte que la coloration des blocs de code illustrés dans votre exemple n'est pas possible:

Vous pouvez également modifier la couleur d'arrière-plan de lignes entières à l'aide de la fonction Signer. (Voir linehldans :help sign.txt)

Cependant, notez que:

1. Pour ce faire, il faut écrire du code pour placer des signes sur chaque ligne qui doit être colorée et les garder à jour lorsque le contenu du fichier change,

2. Par défaut, lorsque vous placez un signe, la colonne du signe sera affichée à gauche de la fenêtre. Il est possible de modifier la coloration de la colonne de signe avec le SignColumngroupe de surbrillance, et dans les versions plus récentes de Vim, il peut être entièrement supprimé. (Voir :help 'signcolumn'.)

Par exemple, pour adapter la solution de Carpetsmoker à l'utilisation du mécanisme de signe (plus robuste), vous pouvez procéder comme suit:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Cela simplifie quelque peu le code et comporte moins de mises en garde que la version de Carpetsmoker.

Le plugin DynamicSigns de @ChristianBrabandt facilite l'utilisation de la fonction Sign à cette fin: il décrit comment l'utiliser pour le faire dans cette réponse .