Comment collecter correctement un tableau de lignes dans zsh

Je pensais que ce qui suit regrouperait la sortie de my_commanddans un tableau de lignes:

IFS='\n' array_of_lines=$(my_command);

de sorte que cela $array_of_lines[1]ferait référence à la première ligne de la sortie de my_command, $array_of_lines[2]à la seconde, etc.

Cependant, la commande ci-dessus ne semble pas bien fonctionner. Il semble également séparer la sortie my_commandautour du caractère n, comme je l'ai vérifié print -l $array_of_lines, ce qui, je crois, affiche les éléments d'un tableau ligne par ligne. J'ai aussi vérifié cela avec:

echo $array_of_lines[1]
echo $array_of_lines[2]
...

Dans une seconde tentative, j'ai pensé que l'ajout evalpourrait aider:

IFS='\n' array_of_lines=$(eval my_command);

mais j'ai eu exactement le même résultat que sans.

Enfin, en suivant la réponse sur les éléments List avec des espaces dans zsh , j'ai également essayé d'utiliser des indicateurs de développement de paramètres au lieu d' IFSindiquer à zsh comment scinder l'entrée et collecter les éléments dans un tableau, à savoir:

array_of_lines=("${(@f)$(my_command)}");

Mais j'ai toujours le même résultat (le dédoublement se produit n)

Avec cela, j'ai les questions suivantes:

Q1. Quels sont les " moyens " appropriés pour collecter le résultat d'une commande dans un tableau de lignes?

Q2. Comment puis-je spécifier IFSde scinder uniquement sur les nouvelles lignes?

Q3. Si j'utilise les indicateurs d'expansion de paramètre comme dans ma troisième tentative ci-dessus (en utilisant @f) pour spécifier le fractionnement, zsh ignore-t-il la valeur IFS? Pourquoi ça n'a pas fonctionné dessus?

TL, DR:

array_of_lines=("${(@f)$(my_command)}")

Première erreur (→ Q2): IFS='\n'définit IFSles deux caractères \et n. Pour définir IFSune nouvelle ligne, utilisez IFS=$'\n'.

Deuxième erreur: pour définir une variable à une valeur de tableau, vous avez besoin des parenthèses autour des éléments: array_of_lines=(foo bar).

Cela fonctionnerait, sauf qu'il supprime les lignes vides, car les espaces consécutifs comptent pour un seul séparateur:

IFS=$'\n' array_of_lines=($(my_command))

Vous pouvez conserver les lignes vides sauf à la toute fin en doublant le caractère d'espacement en IFS:

IFS=$'\n\n' array_of_lines=($(my_command))

Pour que les lignes vides se terminent également, vous devez ajouter quelque chose à la sortie de la commande, car cela se produit dans le remplacement de la commande lui-même, et non lors de son analyse.

IFS=$'\n\n' array_of_lines=($(my_command; echo .)); unset 'array_of_lines[-1]'

(en supposant que la sortie de my_commandne se termine pas par une ligne non délimitée; notez également que vous perdez le statut de sortie de my_command)

Notez que tous les extraits ci-dessus laissent une IFSvaleur différente de celle par défaut, de sorte qu'ils risquent de perturber le code suivant. Pour conserver le paramètre IFSlocal, placez le tout dans une fonction dans laquelle vous déclarez IFSlocal (en veillant également à préserver l'état de sortie de la commande):

collect_lines() {
  local IFS=$'\n\n' ret
  array_of_lines=($("$@"; ret=$?; echo .; exit $ret))
  ret=$?
  unset 'array_of_lines[-1]'
  return $ret
}
collect_lines my_command

Mais je recommande de ne pas jouer avec IFS; à la place, utilisez l' findicateur d'expansion pour fractionner les nouvelles lignes (→ Q1):

array_of_lines=("${(@f)$(my_command)}")

Ou pour conserver les lignes vides qui suivent:

array_of_lines=("${(@f)$(my_command; echo .)}")
unset 'array_of_lines[-1]'

La valeur de IFSimporte peu ici. Je suppose que vous avez utilisé une commande qui se divise IFSpour imprimer $array_of_linesdans vos tests (→ Q3).

Deux problèmes: d’abord, apparemment, les guillemets doubles n’interprètent pas non plus les échappements de barre oblique inversée (désolé pour cela :). Utilisez des $'...'citations. Et selon man zshparam, pour collecter des mots dans un tableau, vous devez les placer entre parenthèses. Donc ça marche:

% touch 'a b' c d 'e f'
% IFS=$'\n' arr=($(ls)); print -l $arr
a b
c
d
e f
% print $arr[1]
a b

Je ne peux pas répondre à votre Q3. J'espère que je n'aurai jamais à savoir de telles choses ésotériques :).

Vous pouvez également utiliser tr pour remplacer newline par space:

lines=($(mycommand | tr '\n' ' '))
select line in ("${lines[@]}"); do
  echo "$line"
  break
done