Comment obtenir les données de fin de l'archive gzip?

J'ai une archive gzip avec des données de fin. Si je le déballe en l'utilisant, gzip -dil me dit: " décompression OK, ordures restantes ignorées " (il en va de même pour gzip -tqui peut être utilisé comme méthode de détection de l'existence de telles données).

Maintenant, je voudrais faire connaissance avec ces ordures, mais curieusement, je n'ai trouvé aucun moyen de les extraire. gzip -l --verboseme dit que la taille "compressée" de l'archive est la taille du fichier (c'est-à-dire avec les données de fin), c'est faux et pas utile. fileest également d'aucune aide, alors que puis-je faire?

Compris maintenant comment obtenir les données de fin.

J'ai créé un script Perl qui crée un fichier avec les données de fin, il est fortement basé sur https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}