Comment faire 7-zip faire tout un tas de dossiers

J'ai obtenu un tas de photos que j'ai dû recadrer en 800x600 pixels. Cela a été facile à faire, mais maintenant je dois les télécharger pour que la famille puisse les voir tous.

La chose est, c'est 500 Mo en images. J'ai décidé de simplement compresser les dossiers séparés, qui contiennent chacun une quantité presque égale d'images. De cette façon, je peux télécharger un couple chaque jour. Faire cela manuellement est un travail très long et difficile. Je me demande s'il existe un moyen de faire gérer 7-zip chaque dossier individuellement?

Je pense que j'aurai besoin d'un fichier batch pour le faire, mais je ne suis pas bon avec ça. J'ai tout mis dans un dossier. Dans les différents sous-dossiers se trouve l'emplacement des images. Ce dont j'ai besoin, c'est que le contenu de ce dossier soit compressé. Je ne sais pas si je peux simplement compresser le dossier avec lui. Je sais que PHP a un module zip, je ne l'ai jamais travaillé, donc je ne sais pas s'il peut gérer le fait que le contenu du zip est un dossier qui contient les éléments, au lieu de simplement les éléments.

Exécutée à partir d'une invite de commandes dont le répertoire de travail est votre My Picturesrépertoire, cette commande créera un fichier zip du contenu de chaque sous-répertoire, en laissant tous les fichiers zip dans votre My Picturesrépertoire.

Edit: J'ai ajouté les guillemets nécessaires pour autoriser les répertoires avec des espaces dans leurs noms.

for /D %%d in (*.*) do 7z a -tzip "%%d.zip" "%%d"

Aussi: La version suivante ne placera pas les fichiers dans un sous-répertoire à l'intérieur du fichier zip, mais à la place dans sa racine:

for /D %%d in (*.*) do 7z a -tzip "%%d.zip" ".\%%d\*"

Sous Windows 7 et supérieur

for /D %d in (*.*) do 7z a -tzip "%d.zip" "%d"

ou

for /D %d in (*.*) do 7z a -tzip "%d.zip" ".\%d\*"

Je n'ai pas pu faire fonctionner la ligne de commande, mais j'ai téléchargé WinRAR et mtone avait raison - WinRAR a une option pour compresser plusieurs dossiers dans leurs propres fichiers ZIP séparés.

Par exemple, C:\Files\Fables 01dans C:\Files\Fables 01.zipet C:\Files\Fables 02dans C:\Files\Fables 02.zip.

Avec WinRAR, ouvrez le dossier qui contient les dossiers que vous souhaitez compresser, puis procédez comme suit:

• Sélectionnez tous les dossiers que vous souhaitez compresser / rarer
• Cliquez sur "AJOUTER" ou Alt+ Aou Commandes -> "Ajouter des fichiers à l'archive"
• Sélectionnez RAR ou ZIP
• allez dans l'onglet "Fichiers"
• Cochez «Mettre chaque fichier dans des archives distinctes» sous la zone Archives

Lorsque vous avez réglé d'autres paramètres que vous aimez, appuyez sur OK et boom: plusieurs fichiers ZIP de plusieurs dossiers. Cela a fonctionné tellement plus facilement que la ligne de commande 7zip.

Juste une légère mise à jour de la réponse de eleven81: Le code ci-dessous crée un fichier batch sur lequel plusieurs éléments peuvent être déposés.

@echo off
if [%1]==[] goto :eof
:loop
7z a -tzip "%~1.zip" "%~1"
shift
if not [%1]==[] goto loop

Ce fichier batch peut ensuite être ajouté au menu contextuel via le registre:

1. créez une nouvelle clé sous [HKEY_CLASSES_ROOT \ Folder \ shell], appelez-la cmd1
2. Modifiez la valeur de la chaîne et appelez-la `` Batch Zip ''
3. créer une autre nouvelle clé sous celle-ci et l'appeler la commande
4. Changez la valeur de ceci en votre chemin, avec des barres obliques doubles

Ainsi, par exemple, mon entrée est "C: \ Users \ Rory \ Dropbox \ _apps \ batch_zip.bat" "% 1"

Une fois que vous faites cela, vous aurez une entrée dans votre menu contextuel pour «Batch Zip» qui compressera par lots tous les dossiers sélectionnés dans des archives distinctes

Cependant, si vous le faites via le menu contextuel, il exécutera malheureusement toutes les opérations simultanément, et comme le savent tous ceux qui ont fait beaucoup de zips et de décompressages, le zippage des dossiers fonctionne beaucoup plus rapidement les uns après les autres que tous en même temps.

Si quelqu'un connaît un moyen de résoudre ce problème dans le registre, veuillez le dire.

Faire glisser les dossiers sélectionnés sur le lot les fera l'un après l'autre.

Astuce: si vos images sont des JPG, elles sont déjà compressées. utiliser 7-Zip en mode «archive» sans compression (niveau de compression: stocker), cela accélérera considérablement le processus.

même si vous utilisez la compression Ultra, vous gagnerez à peine 5%, cela ne vaut certainement pas la peine.

Je pensais en termes d'ajout de pièces jointes.

je ne les enverrais pas en pièce jointe. téléchargez plutôt le sur un soi-disant serveur d'hébergement en un clic (par exemple drop.io, rs, mu, ms, etc., les choix sont nombreux), puis envoyez le lien de téléchargement par e-mail à vos amis et votre famille.

J'ai trouvé la réponse de roryok très utile, il a fourni un batch scriptpour Windowsqui vous permet de classer les drag-&-dropfichiers pour un archivage rapide et automatisé.

Pour utiliser ce script, enregistrez-le simplement avec une .batextension, puis vous pouvez faire glisser et déposer des fichiers et / ou des dossiers sur le fichier de commandes ( ou un raccourci vers le fichier de commandes ).

.ziples fichiers seront créés dans le même répertoire que les fichiers source.
( bien que la destination puisse être modifiée dans le script @archivePath )

Quelques mises à jour que j'ai apportées pour améliorer la facilité de personnalisation et la fonctionnalité globale:

• ajout de variables nommées
• implémenté une forboucle qui parcourt les arguments donnés
  ( ainsi que delayedexpansionpour autoriser les variables d'exécution )
• ifconditions supplémentaires pour différencier filesetfolders
  • cela permet au contenu du dossier d'être ajouté directement à l'archive plutôt que d'enfermer le dossier parent dans l'archive
    ( EG:   \archive.zip\file.txt   VS   \archive.zip\parent_folder\file.txt )
• ajouté un journal des erreurs pour afficher les instances ayant échoué ou afficher un message de réussite s'il n'y a pas eu d'erreurs

@Echo OFF
SetLocal EnableDelayedExpansion



Rem //  7-Zip Executable Path
Set sevenZip="C:\Program Files\7-Zip\7z.exe"



Rem // START: NewLine Variable Hack
Set newLine=^


Rem // END: NewLine Variable Hack !! DO NOT DELETE 2 EMPTY LINES ABOVE !!



Rem //  Set ErrorLog Variables
Set errorCount=0
Set separator=--------------------------------------------------------
Set errorLog=!newLine!!newLine!!separator!!newLine!!newLine!
Set errorPrefix=ERROR @:
Set successMessage=All Files Were Successfully Archived



Rem //  Loop Through Each Argument
SetLocal DisableDelayedExpansion
for %%x in (%*) do (

    Rem //  Use Current Argument To set File, Folder, & Archive Paths
    SetLocal DisableDelayedExpansion
    Set filePath="%%~x"
    Set directoryFiles="%%~x\*"
    Set archivePath="%%~x.zip"
    SetLocal EnableDelayedExpansion

    Rem //  Source Is A Folder
    if exist !directoryFiles! (
            Set sourcePath=!directoryFiles!
    )

    Rem //  Source Is A File
    if not exist !directoryFiles! (
            Set sourcePath=!filePath!
    )

    Rem //  Print Separator To Divide 7-Zip Output
    echo !newLine!!newLine!!separator!!newLine!!newLine!

    Rem //  Add Files To Zip Archive
    !sevenZip! A -TZIP !archivePath! !sourcePath!

    Rem //  Log Errors
    if ErrorLevel 1 (
        Set /A errorCount=errorCount+1
        Set errorLog=!errorLog!!newLine!!errorPrefix!!sourcePath!
    )
)



Rem //  Print ErrorLog
if !errorCount!==0 (
    Set errorLog=!errorLog!!newLine!!successMessage!
)
Echo !errorLog!!newLine!!newLine!!newLine!



Rem //  Keep Window Open To View ErrorLog
pause

7-zip a une option pour décompresser chaque fichier dans son propre dossier (* /), mais il manque les commandes de contexte pour effectuer l'action inverse que vous recherchez.

Cela dit, je me souviens d'avoir fait cette chose exacte en utilisant winrar dans le passé. Il y a une option "archive unique par dossier" ou quelque chose à cet effet.

Obtenez picasa et téléchargez-le dans l'album Web de picasa. Ensuite, tout le monde peut facilement mettre les photos en ligne et les visualiser, et peut même télécharger les originaux (pour que votre famille puisse imprimer les versions plus grandes)