Je veux écrire des informations d'état qui remplacent la dernière ligne lorsque je fais quelque chose.

Dans l'exemple de fichier bat suivant, je veux que le texte soit Step 2écrasé Step 1sur la même ligne dans la sortie de la commande.

echo off

echo Step 1
REM Do some stuff...

echo Step 2
REM do some other stuff...

Ce script fera exactement ce que vous avez demandé:

@echo off

setlocal enableextensions enabledelayedexpansion
for /f %%a in ('copy /Z "%~dpf0" nul') do set "ASCII_13=%%a"

set /p "=Step 1" <NUL
REM Do some stuff...

set /p "=!ASCII_13!Step 2" <NUL
REM do some other stuff...

J'ai trouvé cette réponse en regardant le code dans une bibliothèque de manipulation de caractères de script batch écrite par Dave Benham appelée CharLib .

Cette bibliothèque est capable de créer tous les personnages dans la plage 1..255.

Pour plus d'informations, voir le fil de discussion intitulé "Est-il possible de convertir un caractère à sa valeur ASCII?"

Edit 2017-4-26: Il semble que le code ci-dessus ne fonctionne plus . Je ne sais pas quand ce comportement aurait changé, mais il fonctionnait définitivement. Le CRpersonnage après le =maintenant est supprimé par la setcommande. Ah, cela semble être un changement dans la façon dont setfonctionne entre XP et les versions ultérieures de Windows. Voir l'excellente réponse dans la ligne Écraser dans le fichier de commandes Windows? (dupliquer) pour plus de détails et des exemples de code supplémentaires.

Une alternative consiste alors à mettre un caractère non blanc avant le !ASCII_13!et à le supprimer également, peut-être soit en insérant également un espace arrière (qui ne sera pas supprimé) suivi d'un espace ou en ajoutant des espaces à la fin du chaîne d'invite (qui n'est pas supprimée.)

Par exemple, comme ceci:

@echo off

setlocal enableextensions enabledelayedexpansion
for /f %%a in ('copy /Z "%~dpf0" nul') do set "ASCII_13=%%a"

set /p "=Step 1" <NUL
REM Do some stuff...

set /p "=x!ASCII_13!Step 2 " <NUL
REM do some other stuff...

Pour répondre à la question:

@echo off
CALL :EVALUATE "chr(8)"
SET backspace=%result%
<nul set /p =Step 1
:: DO SOME STUFF....
<nul set /p =%backspace%
<nul set /p =2
:: DO SOME OTHER STUFF....
<nul set /p =%backspace%%backspace%%backspace%%backspace%%backspace%%backspace%
<nul set /p =End   
GOTO:EOF



:EVALUATE           -- evaluate with VBS and return to result variable
::                  -- %~1: VBS string to evaluate
:: extra info: http://groups.google.com/group/alt.msdos.batch.nt/browse_thread/thread/9092aad97cd0f917

@IF [%1]==[] ECHO Input argument missing & GOTO :EOF 

@ECHO wsh.echo "result="^&eval("%~1") > %temp%\evaluate_tmp_67354.vbs 
@FOR /f "delims=" %%a IN ('cscript //nologo %temp%\evaluate_tmp_67354.vbs') do @SET "%%a" 
@DEL %temp%\evaluate_tmp_67354.vbs
::ECHO %result%
@GOTO:EOF

Production:

End

Fondamentalement, ce que le script fait, c'est d'écrire Step 1, puis remonte d'un endroit, écrase 1, et à la fin revient complètement et écrase Step 2avec End.

Je reviens en arrière avec le caractère ASCII spécial 8 qui est le retour arrière. Parce que je ne sais pas comment l'écrire en cmd, j'utilise la fonction: EVALUATE qui exécute la fonction VBS Chr () et place le caractère de retour arrière dans la variable result. Si quelqu'un connaît un meilleur moyen, veuillez en informer.

@echo off
for /F "tokens=1 delims=# " %%a in ('"prompt #$H# & echo on & for %%b in (1) do rem"') do set "BSPACE=%%a"
<nul set /p =Step 1
ping 127.0.0.1 >nul
<nul set /p =%BSPACE%
<nul set /p =2
ping 127.0.0.1 >nul
<nul set /p =%BSPACE%
<nul set /p =3
ping 127.0.0.1 >nul
<nul set /p =%BSPACE%%BSPACE%%BSPACE%%BSPACE%%BSPACE%%BSPACE%
<nul set /p =End.  
pause

EXPLICATION:

for /F "tokens=1 delims=# " %%a in ('"prompt #$H# & echo on & for %%b in (1) do rem"') do set "BSPACE=%%a"

cela mettra le caractère de retour arrière dans la variable BSPACE. Maintenant, pour voir le résultat, tapez:

echo ab%BSPACE%c

production: ac

vous pouvez utiliser cette variable BSPACE plusieurs fois pour supprimer plusieurs caractères.

Maintenant, si vous souhaitez définir un retour chariot dans une variable, utilisez

for /F "usebackq" %%a in (copie / Z "% ~ dpf0" nul) DO (set "cr=%%a")

pour voir le résultat, tapez: setlocal EnableDelayedExpansion & echo asfasdhlfashflkashflksa!CR!***

la sortie sera: ***asfasdhlfashflkashflksa

La réponse de @ davour ci-dessus est également belle mais la réponse de @ timfoden n'a pas fonctionné pour moi.

Tu ne peux pas. Habituellement, vous pouvez réaliser ce genre de chose en incluant un caractère de retour chariot (0x0D) dans le fichier qui replacera le curseur dans la première colonne de la même ligne. Mais dans ce cas, cela ne fonctionne pas; le CR est mangé en silence.

De plus, obtenir le CR là-dedans est un peu délicat et au moins ici impliqué un éditeur de texte. Je vous suggère d'écrire un petit programme utilitaire qui fera cela pour vous, ce n'est en fait pas très difficile. Le petit programme C suivant peut suffire (si vous n'avez pas besoin d'Unicode):

#include <stdio.h>

int main(int argc, char* argv[]) {
  if (argc < 2) return 1;
  printf("\r%s", argv[1]);
}

Il ne fait rien de plus que d'imprimer un caractère CR, puis le texte que vous spécifiez comme premier argument. Utilisation comme suit:

@echo off
<nul set /P X=Step 1
pause>nul 2>nul
over.exe "Step 2"

La dernière ligne est l'appel à ce programme. La deuxième ligne est l'idiome de lot normal pour l'impression de texte sans rupture de ligne de fin (ce qui est important dans ce cas car sinon vous ne pourriez pas écraser la ligne). Vous pouvez tout aussi bien utiliser le programme ci-dessus à cet endroit.

Une manière légèrement hacky, mais la seule où vous pouvez être sûr où vous vous retrouvez, serait d'utiliser clsavant votre sortie pas à pas. Scintillera mais de cette façon, vous écrivez toujours en haut à gauche. Et clobber tout ce qui était visible dans la console (c'est pourquoi je ne le recommanderais pas); la plupart des utilisateurs n'aiment pas trop ça.

Obtenez le caractère de nouvelle ligne, écrivez l'étape suivante, revenez au début de la ligne, écrivez la ligne suivante:

@echo off
cls
setlocal enabledelayedexpansion
echo Here's how it's done:

for /f %%a in ('copy /Z "%~f0" nul') do set "Newline=%%a"
set /p "=Step 1!Newline!" <NUL
REM Do some stuff...
ping -n 2 localhost > nul
set /p "=Step 2!Newline!" <NUL
ping -n 2 localhost > nul
set /p "=Step 3 " <NUL
REM do some other stuff...
ping -n 2 localhost > nul
echo:
echo Done.

Vous auriez besoin d'une bibliothèque de curseurs d'écran comme cursesou ncurses, mais je ne connais pas trop leur utilisation. Les deux bibliothèques ont été développées pour les systèmes Unix, mais vous pouvez les trouver pour Windows (dans l' environnement Cygwin ou GnuWin32 ).

Je ne connais aucun moyen facile d'y accéder dans un fichier batch de style DOS. Vous feriez peut-être mieux de programmer dans un langage compilé. Jetez un œil au Ncurses HOWTO pour avoir une meilleure idée de son utilité.

Solution 1

Avec Notepad ++, il est possible d'insérer le Backspace ←caractère (ASCII 0x08) directement, en utilisant son panneau d'insertion de codes ASCII (Édition> Panneau de caractères).

Ma solution consiste à insérer le [BS]caractère directement puis, comme les autres solutions publiées ici, à l'utiliser plusieurs fois pour supprimer les caractères précédents:

Code

@ECHO OFF

SET "BACKSPACE_x7=[BS][BS][BS][BS][BS][BS][BS]"

SET /P "DUMMY_VAR=Step 1" < NUL
REM Do some stuff...

SET /P "DUMMY_VAR=%BACKSPACE_x7%Step 2" < NUL
REM Do some other stuff...

GOTO :EOF

Capture d'écran du Bloc-notes ++

Production

Solution 2

Une autre possibilité consiste à utiliser cecho (commande echo avec prise en charge des couleurs) pour insérer un Carriage Return ↵comme caractère unicode (U + 000D):

Code

@ECHO OFF

SET CARRIAGE_RETURN={\u000D}

cecho Step 1
REM Do some stuff...

cecho %CARRIAGE_RETURN%Step 2
REM Do some other stuff...

GOTO :EOF

NB: cecho_x64.exetourne beaucoup plus vite sur ma machine que cecho.exe.