Puis-je faire en sorte que MS Word insère des symboles pour les sauts de ligne automatiques?

Je souhaite inclure un schéma XML dans un document technique créé avec MS Word. Les lignes étant beaucoup plus longues que la largeur disponible sur la page, Word les coupe automatiquement. Je tiens à préciser clairement au lecteur où cela s'est produit, afin qu'ils sachent que la ligne suivante est la continuation de la précédente. Existe-t-il un moyen de forcer Word à insérer automatiquement un symbole, par exemple, à la fin de chaque ligne automatiquement interrompue?

Je pourrais bien sûr le faire manuellement, mais ce serait beaucoup de travail que je devrais répéter à chaque changement de schéma, ce qui risquerait de provoquer des erreurs. Je connais le mode "Afficher les caractères non imprimables", mais je souhaite que ces symboles soient uniquement visibles dans cette section et également imprimés. En outre, "Afficher les caractères non imprimables" affiche les sauts de ligne explicites au lieu de ceux automatiques.

Est-ce possible avec MS Word, ou si non, quelqu'un peut-il recommander une autre technique automatisée pour y parvenir?

Eh bien, vous pouvez essayer la VBA suivante comme point de départ, mais je pense que cela nécessitera du travail. Cela suppose que vos sauts seront toujours après un espace (ce qui n'est pas déraisonnable pour un schéma IMO), donc si vous avez un texte sans espace plus long qu'une ligne, vous devrez peut-être toujours le casser à la main.

Ceci remplace les espaces finaux par le symbole de retour dans la police en cours + un espace de séparation sans largeur, aussi longtemps que vous pouvez ajuster la largeur du symbole de retour (il existe différentes façons de le faire) de sorte que Word mêmes points, cela peut suffire.

Sub markAutoLineBreaks()
' Changes line breaks automatically made by Word
' into "return" charaters, but only where the line
' ends in a " "
' This operates on the text in the current selection
' We use a character style
Const strStyleName As String = "contchar"
Dim r As Word.Range
Dim styContchar As Word.Style

' Add the style if it is not present
On Error Resume Next
Set styContchar = ActiveDocument.Styles.Add(strStyleName, Type:=WdStyleType.wdStyleTypeCharacter)
Err.Clear
On Error GoTo 0
' Set the characteristics of the style. What you need to aim for
' is to adjust the character width so that the text breaks at the
' same point (if possible)
Set styContchar = ActiveDocument.Styles(strStyleName)
With styContchar.Font
  .Size = 8
End With

' Save the selection
Set r = Selection.Range

' remove old line end marks
With Selection.Find
  .ClearFormatting
  .Style = styContchar
  .Replacement.ClearFormatting
  ' Not sure what to use here, but this will have to do
  .Replacement.Style = ActiveDocument.Styles("Default Paragraph Font")
  ' 9166 is the return character. 8204 is a No-width breaking space
  .Text = ChrW(9166) & ChrW(8204)
  .Replacement.Text = " "
  .Forward = True
  .Format = True
  .MatchCase = False
  .MatchWholeWord = False
  .MatchWildcards = False
  .MatchSoundsLike = False
  .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll

' Moving down lines is not completely straightforward
' but this seems to work
Selection.Collapse direction:=wdCollapseStart
Do Until Selection.End > r.End
  Selection.Bookmarks("\line").Select
  If Right(Selection, 1) = " " Then
      Selection.SetRange Selection.End - 1, Selection.End
      Selection.Delete
      Selection.Text = ChrW(9166) & ChrW(8204)
      Selection.Style = styContchar
      Selection.Bookmarks("\line").Select
      Selection.Collapse direction:=wdCollapseStart
  End If
  Selection.MoveDown wdLine, 1, False
Loop

' reselect our original selection
r.Select
Set r = Nothing
End Sub

Je ne l'exprimerai pas en double, car ce n'est pas une question à réponse, mais vous voudrez peut-être regarder ici:
est-il possible de définir un style pour afficher les continuations de lignes dans Microsoft Word?

ce qui vous amène à: Convertir HTML en image