Comment ouvrir une application console avec une taille de fenêtre donnée?

L'application que je veux démarrer est MongoDB. Si je voulais le démarrer normalement, cela ressemble à ceci:

Je n'aime pas le nombre de sauts de ligne et j'ai beaucoup d'espace sur l'écran, donc je voudrais utiliser cet espace pour me débarrasser des sauts de ligne.

Je peux changer la taille de la fenêtre de console avec MODE, j'ai donc écrit un fichier batch comme ceci:

@ECHO OFF
MODE con:cols=140 lines=70
%~dp0mongodb\bin\mongod --dbpath %~dp0data --rest

Jusqu'ici tout va bien. Lorsque je démarre ce fichier de commandes, j'obtiens une fenêtre plus grande, comme souhaité.

Mais lorsque j'appuie maintenant sur Ctrl+ Cpour quitter MongoDB, j'obtiens l'invite agaçante:

Terminate batch job (Y/N)?

Ce qui est inutile, car la commande que je viens de quitter était de toute façon la dernière commande du travail par lots et quelle que soit ma réponse, le résultat est le même.

Alors, comment puis-je obtenir une fenêtre de console plus grande pour l'application sans avoir cette invite lorsque j'appuie sur Ctrl+ C?

J'ai passé quelques heures aujourd'hui à implémenter une petite application C # qui peut envelopper une autre application console et ajuster la taille de la fenêtre de l'hôte de la console.

console-wrapperest facile à utiliser. Il n'attend que quelques paramètres de ligne de commande:

Usage: console-wrapper.exe [OPTIONS]

Options:

      --subject=VALUE        The application that should be started by the
                               console wrapper.
      --width=VALUE          The desired width of the console window.
      --height=VALUE         The desired height of the console window.
  -h, -?, --help             Shows this help message

--widthet --heightsont utilisés pour définir la taille de la fenêtre de console résultante. --subjectpeut être utilisé en option, s'il est omis, les paramètres restants sont traités comme la commande (avec paramètres) pour démarrer.

Donc, le dernier appel que j'utilise maintenant dans notre script de démarrage est:

START "MongoDB" database\console-wrapper.exe --width=140 --height=70 %~dp0database\mongodb\bin\mongod.exe --dbpath %~dp0database\data --rest

La fenêtre résultante aura la taille demandée et en appuyant sur Ctrl+ C, la fenêtre se fermera (après avoir correctement arrêté le processus contenu).

Avez-vous envisagé de l'exécuter à partir d'un script PowerShell? Powershell est capable de redimensionner sa propre fenêtre

$h = Get-Host
$buf = $h.UI.RawUI.BufferSize
$buf.Width = 300
$h.ui.rawui.BufferSize = $buf
$win = $h.UI.RawUI.WindowSize
$win.Width = 150
$h.ui.rawui.WindowSize = $win
#Command to start mongodb here.

Cela crée une fenêtre d'une taille de 150 mais a également un tampon défilant latéralement de 300.

Pour autant que je comprends la question, vous voulez que MongoDB ait la taille spécifiée de la fenêtre de console et se ferme lorsque vous appuyez sur Ctrl+ C. Ensuite, la réponse est assez simple: utilisez le raccourci pour le démarrer.

Je n'ai pas d' mongodexécutable, donc je l'utiliserais perl.execomme exemple. Lorsque vous le démarrez à partir de la boîte de dialogue Exécuter ( Windows+ R), la taille de la fenêtre de la console est de 80 × 25 standard avec une taille de tampon de 300 lignes.

1. Créez un raccourci vers mongod(ou perldans mon cas).
2. Cliquez avec le bouton droit sur le raccourci et cliquez sur Propriétés .
   1. Dans l' onglet Raccourci du champ Cible , ajoutez des paramètres à mongod.
   2. Le champ Démarrer dans contrôle le répertoire courant initial du programme démarré. Par défaut, ce sera le répertoire où se trouve .exe.
3. Cliquez sur l' onglet Disposition .
   1. Modifiez la taille de la fenêtre à 140 × 70.
      
   2. Vous pouvez augmenter la taille du tampon Hauteur de l' écran à 1 000 ou plus pour pouvoir faire défiler les messages plus anciens.
   3. Si vous désactivez la fenêtre Laisser la position du système , vous pouvez spécifier l'emplacement de la fenêtre de la console à l'écran.
4. Cliquez sur OK pour fermer les propriétés de raccourci.

Maintenant, lorsque vous cliquez sur ce raccourci, la fenêtre de la console aura la taille spécifiée. Lorsque vous appuyez sur Ctrl+ C, l'application se ferme et la fenêtre se ferme sans aucune invite supplémentaire.

Vous pouvez également modifier la disposition de la fenêtre après l'avoir lancée à partir de la boîte de dialogue Exécuter . Cliquez avec le bouton droit sur le titre de la fenêtre de console et cliquez sur Propriétés . Cliquez sur l' onglet Disposition , ajustez la taille de la fenêtre et cliquez sur OK pour fermer les propriétés et appliquer immédiatement les modifications. (Si la fenêtre a été démarrée à partir du raccourci, les propriétés du raccourci sont mises à jour.)

La prochaine fois que vous lancerez la même application, la taille de la fenêtre de la console sera comme par magie la même taille. (Je ne l'ai pas vérifié cette fois mais cela fonctionnait.)

Les paramètres de disposition de la console par défaut se trouvent ici dans le registre:

[HKEY_CURRENT_USER\Console]

Vous pouvez modifier ces paramètres et ils s'appliqueront à TOUTES les fenêtres de commandes qui se lancent, quel que soit le chemin. Malheureusement, les valeurs brutes ne sont pas favorables à l'homme.

Pour les définir comme vous le souhaitez, ouvrez une fenêtre cmd normale, puis modifiez les paramètres à votre guise. Regardez dans le registre au chemin ci-dessus et vous devriez voir une sous-clé sous "Console" pour cmd.exe. Exportez cette clé dans un fichier, modifiez le chemin d'accès ci-dessus et importez, ou copiez simplement manuellement les valeurs de l'une à l'autre. Vous pouvez ensuite supprimer l'entrée spécifique cmd.exe. Maintenant, toutes les fenêtres de commandes qui s'ouvrent utiliseront les valeurs par défaut modifiées.

Je l'ai trouvé pratique pour créer quelques fichiers d'entrée de registre avec mes valeurs par défaut standard afin que je puisse facilement les faire apparaître sur un nouveau serveur lorsque je RDP pour la première fois. J'ai fait des préréglages pour les deux tailles que j'utilise généralement.

Pour 1024 x 768 (je l'utilise pour les serveurs normalement accessibles via un outil RDP multi session):

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:012c0050
"WindowSize"=dword:00190050
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

Pour 1280 x 1024:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:0bb800af
"WindowSize"=dword:004b00af
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

Mettez la Startcommande devant l'appel de mongodb. Je crois que cela devrait le réparer.

Si vous êtes heureux d'exécuter un fichier batch avec quelques petits programmes d'assistance, une solution complète est publiée par moi ici:
Comment un fichier batch peut-il exécuter un programme et définir la position et la taille de la fenêtre?

Contenu comme ci-dessous. . . .

Ce fichier batch de démonstration exécutera un programme en ligne de commande et définira la position et la taille de sa fenêtre de console d'invite de commandes. Le thème général de ce lot est le même que les deux solutions précédentes (sur la page Débordement de pile dans le lien ci-dessus), mais il y avait quelques problèmes et solutions de contournement uniques pour que cela fonctionne - ceci est une fenêtre d'invite de commandes hébergée par 'CMD .EXE 'et non une fenêtre GUI comme' EXPLORER.EXE '.

Lisez tous les commentaires et la description dans le fichier batch pour plus d'informations.

Outils utilisés:
1.   MonitorInfoView  par Nir Sofer (41 Ko)
2.   NirCmd  par Nir Sofer (43 Ko)
3.   GetPIDs  par Daniel Scheibli (280 Ko)
4.   upx.exe  --- est le programme en ligne de commande que nous utiliserons pour cette démo; placez-le dans le même répertoire que le fichier de commandes.
5. Un fichier batch --- voir ci-dessous

Rassemblez les cinq fichiers dans un répertoire. Il s'agit du fichier batch, prêt à fonctionner sur n'importe quel système Windows.

Ce que ce lot de démonstration va faire, à part vous présenter une fenêtre de console personnalisée, c'est qu'il s'exécutera upx.exeavec les commutateurs de ligne de commande--best -v -o getpids-compressed.exe getpids.exe. Nous allons compresser notre outil «GetPID» jusqu'à 88 Ko ........ Après le lancement, double-cliquez sur la barre de titre de cette fenêtre de console pour voir un phénomène intéressant; cette fenêtre de console se comporte comme une interface graphique!

@echo off
setlocal enabledelayedexpansion enableextensions
pushd %~dp0%

REM ----- ADD SOME USEFUL INFORMATION TO THIS CONSOLE WINDOW TITLE.
for /f "tokens=3" %%A in ('getpids.exe') do set _PROCESS_ID_=%%A
title This batch file runs a command-line program and sets the position and size of its console window        (PROCESS ID = %_PROCESS_ID_%)

REM ********************** DESCRIPTION ************************************
REM ** This script opens a command-line program console window with specified
REM ** screen properties at the primary monitor (containing the taskbar).
REM ** The "X/Y position" and "W/H size" of the console window is auto-set by
REM ** this script and the monitor resolution is auto-calculated to suit.
REM ** 'MonitorInfoView.exe' is the helper tool used to capture the resolution
REM ** info of the monitor.
REM ** 'nircmd.exe' is the tool performing all the display trickery.
REM ** 'getpids.exe' is the helper tool used to capture the Process ID of the
REM ** working batch file, thus allowing us to identify which CMD.EXE host this
REM ** console window belongs to when looking at Task Manager.
REM **
REM ** To tweak this script, go to the code section named:
REM ** >>>>> USER INPUT/PREFERENCES ARE ALL SET HERE <<<<<
REM ***********************************************************************

REM ----- CLEAR ANY PREVIOUS JOB OUTPUTS IF THEY EXIST
if exist ~TMP.TXT type NUL > ~TMP.TXT

REM ----- OUTPUT THE PRIMARY MONITOR INFORMATION TO A TEXT FILE
MonitorInfoView.exe /hideinactivemonitors 1 /stext ~TMP.TXT

REM ----- ISOLATE THE RESOLUTION LINE, REMOVING ALL THE OTHER LINES IN THE TEXT FILE
for /f "delims=" %%A in ('type "~TMP.TXT" ^|find.exe /i "Maximum Resolution"') do echo %%A>~TMP.TXT

REM ----- GET THE RESOLUTION NUMBERS, AND SET THEM AS VARIABLES
for /f "tokens=3,4 delims=:X " %%A in ('type "~TMP.TXT"') do set _SCREENW_=%%A& set _SCREENH_=%%B


REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [BEGIN] <<<<<<<<<<<<

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  FILE NAME (WITH EXTENSION)
REM ----- |
REM ----- | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR)
REM ----- | |ALSO READ THE NEXT COMMENTS ABOUT SETTING SWITCHES   

    set _MYPROGRAM_=upx.exe

REM ----- ----------------------------------------   
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  SWITCHES (TO BE PASSED TO THE PROGRAM)
REM ----- |
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF RUNNING THE PROG WITHOUT ANY PARAMETERS
REM ----- | | 
REM ----- | | |IF THE VALUE CONTAINS THE CHARS  '|'  OR  '<'  OR  '>'  THIS BATCH WILL FAIL TO RUN !!!
REM ----- | | |
REM ----- | | | |YOU CAN APPEND EXTRA TEXT TO THE END OF THE COMMAND BY USING THE AMPERSAND CHARACTER '&'
REM ----- | | | | EXAMPLES:
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4 & this text will be ignored; useful for adding some inline comments.
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4         & this works too, and the extra blank spaces will also be ignored.
REM ----- | | | | 
REM ----- | | | | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR), PATH ARGUMENTS MUST POINT TO A SPECIFIC LOCATION
REM ----- | | | | |AND BE ABSOLUTE OR INCLUDE ENVIRONMENT VARIABLES, AND ALWAYS ENCLOSE PATHS IN QUOTES.
REM ----- | | | | | EXAMPLES:
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type %0                                       <<<<<<<this batch file (quotes are optional; the only exception to the rule)
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\File.txt"                     <<<<<<<goes back one Dir from this batch file
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\SomeFolder\File.txt"          <<<<<<<goes back one Dir from this batch file and then forwards into "SomeFolder"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4          <<<<<<<displays directory listing of the System folder. NOTE: 'dir' by itself and
REM ----- | | | | |                                                                                without a specific path argument will resolve to the folder of this batch file.

    set _MYPROGRAMSWITCHES_=--best -v -o getpids-compressed.exe getpids.exe      &// original is 280 KB, will compress down to 88 KB

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  DIRECTORY PATH (OF THE PROGRAM)
REM ----- | 
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF THE PROG IS AT SAME LOCATION AS BATCH
REM ----- | |THIS VARIABLE WILL BE IGNORED IF THE PROG IS 'CMD.EXE'
REM ----- | | 
REM ----- | | EXAMPLES:
REM ----- | | set _MYPROGRAMDIR_=.\                               <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  dot backslash *OR* dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%                            <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  same locatiion as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=..\                              <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  dot dot backslash *OR* dot dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%\..                         <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  same as location as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=%SYSTEMROOT%\..\My Utilities     <<<<<<<relative path, program is back one directory from the Windows folder
REM ----- | |                                                                  and then forwards into the folder 'My Utilities'
REM ----- | | set _MYPROGRAMDIR_=C:\My Utilities\                 <<<<<<<absolute path, enclosing quotes are optional; trailing backslash is optional
REM ----- | |                                                                  same location as previous

    set _MYPROGRAMDIR_=

REM ----- ----------------------------------------
REM ----- |SET THE WANTED DIMENSIONS OF THIS CONSOLE WINDOW

    set /a _WINW_=(%_SCREENW_% / 2) + 250
    set /a _WINH_=(%_SCREENH_% / 2) + 150
    set /a _WINX_=(%_SCREENW_% - %_WINW_%) / 2
    set /a _WINY_=(%_SCREENH_% - %_WINH_%) / 2

REM ----- ----------------------------------------
REM ----- |STYLE THIS CONSOLE WINDOW   !!!IMPORTANT!!!
REM ----- |
REM ----- | |IF WE DO NOT USE THE 'MODE' COMMAND HERE ALONG WITH ITS 'COLS/LINES' VALUES THEN
REM ----- | |THE POSITIONING/SIZING OF THIS WINDOW BY 'NIRCMD.EXE' FURTHER DOWN WILL NOT WORK !!!
REM ----- | |
REM ----- | | |SOME COMMANDS WILL OUTPUT A LOT OF LINES AND AND THE CONSOLE DISPLAY WILL BE TRUNCATED
REM ----- | | |RUN THIS FOR AN EXAMPLE=====>   cmd.exe dir "%systemroot%\system32" /a/o/s/4   <=====
REM ----- | | |TO SOLVE THIS PROBLEM, SET THE 'LINES' VALUE OF 'MODE' TO A VERY HIGH NUMBER
REM ----- | | |THE MAXIMUM NUMBER IS 32000 (ON MY SYSTEM); 'MODE' WILL BE IGNORED IF THE NUMBER IS HIGHER !!!   

    color 0A
    mode.com con:cols=%_SCREENW_% lines=10000

REM ----- ----------------------------------------
REM ----- |DELETE THE TEMP TEXT FILE MADE BY 'MonitorInfoView.exe'
REM ----- |COMMENT OUT THE LINE IF YOU DON'T CARE ABOUT DELETING IT

    del /f /q ~TMP.TXT 2>nul >nul

REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [END] <<<<<<<<<<<<<<
REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


REM ----- RUN THE TASK . . .
nircmd.exe win setsize foreground %_WINX_% %_WINY_% %_WINW_% %_WINH_%
popd

if not defined _MYPROGRAMDIR_ set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == "." set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == ".\" set _MYPROGRAMDIR_=%~dp0
pushd %_MYPROGRAMDIR_%
if not exist %_MYPROGRAMDIR_% goto _SKIP_
set _CONVERT_PATH_="%CD%"
set _CONVERT_PATH_=%_CONVERT_PATH_:"=%
set _MYPROGRAMDIR_=%_CONVERT_PATH_%
:_SKIP_
popd

echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
if "!_MYPROGRAM_!"=="cmd.exe" (echo PROGRAM DIR ..........: %SYSTEMROOT%\system32) else (echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!)
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================

if "!_MYPROGRAM_!"=="cmd.exe" (goto _PROGRAM_IS_CMD_) else (goto _PROGRAM_IS_OTHER_)

:_PROGRAM_IS_CMD_
cd /d "%SYSTEMROOT%\system32"
!_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_PROGRAM_IS_OTHER_ 
cd /d "!_MYPROGRAMDIR_!"
if "%CD%\!_MYPROGRAM_!" == "%CD%\" goto _ERRORMESSAGE_
if not exist "%CD%\!_MYPROGRAM_!" goto _ERRORMESSAGE_
"!_MYPROGRAMDIR_!\!_MYPROGRAM_!" !_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_ERRORMESSAGE_
cls
color 4F
echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================
echo                        ^^!^^!^^!  E R R O R  ^^!^^!^^!
echo.
echo The program has failed to run; the path set by the above values does not exist.
echo Please exit this window and check the values you have set in this batch file.
echo.
echo This batch file is located here:
echo %0
echo. & echo. & echo. & echo. & echo.

:_END_

REM ----- CLEAR VARIABLE VALUES FROM MEMORY . . .
set _PROCESS_ID_=
set _SCREENW_=
set _SCREENH_=
set _MYPROGRAM_=
set _MYPROGRAMSWITCHES_=
set _MYPROGRAMDIR_=
set _WINW_=
set _WINH_=
set _WINX_=
set _WINY_=
set _CONVERT_PATH_=

REM ----- STOP THIS CONSOLE WINDOW FROM CLOSING   !!!IMPORTANT!!! . . .
REM ----- |
REM ----- | http://superuser.com/questions/306167/how-to-prevent-the-command-prompt-from-closing-after-execution
REM ----- | | by 'kitsu.eb' (April 26, 2014)
REM ----- | | | "My solution (just tested on Win7) is to add CMD as the last line in the batch file.
REM ----- | | |  This runs a nested command prompt that inherits the environment of its parent.
REM ----- | | |  That child shell holds the batch process open until you EXIT, at which point the
REM ----- | | |  batch has no child processes and also exits."
REM ----- | Comment . . .
REM ----- | | by me
REM ----- | | | "This is a workaround. You can't use PAUSE as the last command to stop this window from closing
REM ----- | | |  because the window will terminate after you press a key. While this batch is running, if you open
REM ----- | | |  Task Manager/Process Hacker/Process Explorer you will see an extra CMD.EXE child process running
REM ----- | | |  under the parent CMD.EXE of this batch file."
cmd.exe