EXCEL: FORMATEZ un “jan” “feb” “mar” “apr” en un MOIS (01,02,03)

S'il vous plaît, quelqu'un sait:

Date----------------Result--------------------------------------What I want!
9.99 LATE AUG 13 ---IF(ISNUMBER(SEARCH("aug",B2&" "&C2)),"08"---08
9.99 Early Sept 13 ----"""--------------------------------------09

si j'utilise pour tous les 12 mois, alors cela donne une erreur: - la formule spécifiée ne peut pas être entrée car elle utilise plus de niveaux d'imbrication que ceux autorisés

pour par exemple: -

  (B2)------------------(C2)

HK-753F (6) TARD LE 13 AOÛT ------- MERC

HK-754F (6) ------------------------ TÔT LE 13 SEPT

11.99 -------------------------------- TARD 13 SEPTEMBRE

10.99 13 JUIN --------------------- MERC

microsoft-excel

— John
source

Quel est le format des autres cellules que vous avez? Et pourquoi avez-vous concaténé B2 et C2?

— Jerry

sa survenue possible en B2 et C2. autre format de cellule donné à la question

— John

D'accord. Est-ce toujours 9.99 Lateou 9.99 Early? Et quand vous dites que cela peut être en B2 et C2, peut-il y avoir du texte dans les deux?

— Jerry

Non, parfois, on dirait que HK-753F (6) LE 13 AOÛT 13 (B2 et C2) ont un texte, mais "jan" "feb" ne figure que dans une cellule.

— John

@Sandy Editez votre message et donnez-nous quelques exemples corrects, incluant tous vos cas, au lieu de ces commentaires.

— Jan Doggen le

Essayez cette formule

=MATCH(2^15,SEARCH({"jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec"},B2&" "&C2))

ou une version légèrement plus courte mais moins transparente ....

=MATCH(2^15,SEARCH(TEXT(29*{1,2,3,4,5,6,7,8,9,10,11,12},"mmm"),B2&" "&C2))

Explication

Lorsque vous faites un SEARCH"tableau" de termes tels que {"jan", "feb", "mar", "apr", "may", "jun", "jul", "août", "sep", " oct "," nov "," dec "} alors le résultat est aussi un tableau, un #VALUE! erreur pour chaque terme qui n'existe pas dans B2 & "" & C2 et un nombre (la position) si c'est le cas, donc si B2 & "" & C2 = HK-753F (6) FIN AOÛT 13 MERC, le résultat de

=SEARCH({"jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec"},B2&" "&C2)

est le tableau suivant:

{#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,#VALUE!,17,#VALUE!,#VALUE!,#VALUE!,#VALUE!}

Notez que toutes les entrées sont des erreurs à l'exception de 17 en position 8 (17 est la position du "A" de "AUG" dans B2 & "" & C2).

Lorsque MATCHfunction (sans 3ème argument) recherche un "bignum" comme 2 ^ 15 dans ce tableau, il correspond toujours au dernier nombre, de sorte que le résultat est 8 (car "aug" est le 8ème dans la liste des mois)

— Barry Houdini
source

Merci cela fonctionne mais j'ai besoin du format "01" "02" et non d'un "1", "2". Avez-vous un point de résolution pour la première formule?

— John

@saNdy Vous pouvez l'envelopper TEXT()comme ceci:=TEXT(MATCH(2^15,SEARCH(TEXT(29*{1,2,3,4,5,6,7,8,9,10,11,12},"mmm"),B2&" "&C2)),"00")

— Jerry

= MATCH (2 ^ 15, SEARCH ({"jan", "feb", "mar", "apr", "may", "jun", "jul", "août", "sep", "oct", "nov", "déc"}, B2 et "" & C2)) dans celui-là s'il vous plaît.

— John

@saNdy C'est fondamentalement la même chose:=TEXT(MATCH(2^15,SEARCH({"jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec"},B2&" "&C2)),"00")

— Jerry

Merci @jerry, vous m'aidez beaucoup dans ce dossier. En fait, je suis le débutant en cela. Merci encore.

— John