Comment puis-je mettre à jour automatiquement Flash Player chaque fois qu'une nouvelle version est publiée?

Résumé:

Flash Player Update Service ne fonctionne pas sur un calendrier fiable et ne télécharge pas automatiquement et appliquer les mises à jour quand il ne fonctionne.

Étant donné l'importance d'avoir une version à jour de Flash Player installée (pour ceux d'entre nous qui n'utilisent pas Chrome avec son lecteur intégré), je voudrais trouver un moyen de garantir que les nouvelles mises à jour sont rapidement détectées et installé.

Ce qui suit sont les détails de mes efforts pour résoudre ce problème par moi-même ...

Annexe A: Service de mise à jour de Flash Player

OK, retour dans Flash Player 11.2 (ou alors?) Adobe a ajouté le service de mise à jour de Flash Player (FlashPlayerUpdateService.exe), il était censé garder Flash Player à jour ...

• Lors de l'installation, FPUS est configuré pour s'exécuter en tant que service Windows, avec le type de démarrage défini sur Manuel.

• Une tâche planifiée (Adobe Flash Player Updater.job) est ajoutée pour démarrer ce service toutes les heures.

Jusqu'à présent, tout va bien - cette configuration évite d'avoir un service en cours d'exécution, mais s'assure que les contrôles sont exécutés assez souvent pour détecter rapidement les mises à jour. Le programme de mise à jour du logiciel de Google est configuré de la même manière, et cela fonctionne très bien ...

... Et pourtant, quand j'ai vérifié la version de mon Flash Player installé, j'ai trouvé que c'était le 11.6.602.180 , qui, d'après l'examen des horodatages des fichiers, a C:\Windows\System32\Macromed\Flashété mis à jour (ou installé) le mar 12 mars, 2013 --- 12/03/13, 17h00:08 .

J'ai fait cette observation le jeu 25 avril 2013 --- 25/04/13, 19:00:00 , et après avoir vérifié le site Web d'Adobe , j'ai constaté que la version actuelle de Flash Player était 11.7.700.169 .

Cela fait plus d'un mois depuis la dernière mise à jour, avec une nouvelle clairement disponible sur le site Web mais sans aucune indication que le contrôle horaire exécuté sur ma machine l'a remarqué ou a l'intention de le télécharger.

Annexe B: exécution manuelle du programme de mise à jour de Flash Player

Il était une fois, courir vous donnerait une fenêtre avec un bouton Installer ; appuyer dessus téléchargerait le programme d'installation de la version actuelle (automatiquement, sans ouvrir de navigateur) et l'exécuterait, puis vous cliqueriez sur ce programme d'installation et vous auriez terminé. C'était manuel, mais ça a marché! Trouver mon installation actuelle obsolète (voir l'annexe A), j'ai d'abord essayé ce processus de mise à jour manuelle. Pourtant...FlashUtil32_<version>_Plugin.exe -update plugin

• En cours d'exécution (dans mon cas, c'est ) ... ne présente qu'une fenêtre avec un bouton Télécharger, cliquer sur ce bouton Télécharger ouvre mon navigateur à l'URL https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• En cours d'exécution (dans mon cas, c'est ) ... ne présente qu'une fenêtre avec un bouton Télécharger, cliquer sur ce bouton Télécharger ouvre mon navigateur à l'URL https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Je pourrais continuer avec la page de téléchargement vers laquelle il m'a été envoyé, décochez la case Foistware ("Free! McAfee Security Scan Plus"), téléchargez ce programme d'installation (ActiveX, pas de foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, pas de foistware: install_flashplayer11x32au_mssd_aih.exe) & ont probablement un Flash mis à jour ... mais alors, quel est l'intérêt du service de mise à jour de Flash Player si je dois télécharger et exécuter manuellement un autre exe?

Épilogue

Depuis, je soupçonne que le service de mise à jour est intentionnellement entravé pour conduire les premiers utilisateurs à la page de téléchargement manuel. Si cela est vrai, il n'y a probablement pas de solution à cette question d'écrire mon propre programme de mise à jour; j'espère que je me trompe.

Peut-être que le programme de mise à jour applique uniquement les mises à jour de la gamme 11.6.x?

Vous pouvez toujours utiliser des liens directs vers les installateurs, que je trouve plus fiables: ActiveX ; Plugin .

Avec ce fichier .bat , il essaiera de mettre à jour ou d'installer automatiquement Flash Player pour Internet Explorer, Firefox (SeaMonkey et etc.), basé sur Chrome (Chrome, Opera 15+ et etc):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Wget requis que vous pouvez télécharger ici et devez le placer dans le même répertoire où .bat a été placé.

Un exemple un peu plus avancé écrit dans Autoit .

Caractéristiques: Vérifiez simplement la nouvelle version, s'il n'y a pas de nouvelle version, quittez le programme sans télécharger le programme d'installation de Flash Player. Si le programme d'installation de téléchargement a échoué, affichez une boîte de message avec une erreur et quittez. Fenêtre d'invite de commande masquée. Pas besoin de wget.

Après avoir installé Autoit et Editor . Faites un clic droit sur le bureau-> Nouveau-> Script d'auto. Faites un clic droit sur ce fichier créé-> Modifier. Maintenant, vous devriez voir la fenêtre ScITE et après la ligne "Ajoutez votre code ci-dessous ici" ajoutez ce code:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Ensuite, dans la fenêtre SciTE, appuyez sur Tools-> Build ou appuyez sur F7. Maintenant, vous obtiendrez un exécutable autonome dans le même répertoire où se trouvait le script Autoit.

Je recommande de créer un nouveau dossier (avec une autorisation d'accès en écriture) pour ce "programme de mise à jour". Vous pouvez ajouter un raccourci vers ce "programme de mise à jour" pour démarrer également.

Voici l' application pour désinstaller le lecteur flash.

Juste, je veux partager mon script batch avec vous, enregistrez simplement ce morceau de code dans votre bloc-notes et nommez-le comme Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************