Dans Outlook2010, existe-t-il un moyen d'afficher les rappels actuellement en attente?

Existe-t-il un moyen dans Outlook 2010 pour afficher une liste d'éléments actuellement mis en attente? Par exemple, disons que dans deux semaines, j'ai défini un rappel pour apparaître vendredi pour un déjeuner important le lundi suivant (j'aime me souvenir des tâches du lundi avant le week-end). Lorsque le rappel apparaît vendredi, je le répète pendant trois jours afin qu'il réapparaisse juste avant le déjeuner de lundi. Puis lundi roule et ma mémoire est floue et je suis un peu paranoïaque que j'ai accidentellement rejeté le rappel vendredi au lieu de le répéter correctement. Je peux toujours voir le rendez-vous d'origine sur mon calendrier, mais je dois m'assurer que le rappel s'affichera quand je m'y attendrai pour ne pas manquer ma réunion.

Existe-t-il un moyen dans Outlook 2010 pour afficher une liste des rappels actuellement mis en attente? Cela serait également utile dans les cas où j'effectue une tâche dont j'ai rappelé le rappel jusqu'à plus tard, et je souhaite maintenant afficher le rappel répété et l'annuler.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Si vous n'êtes pas familier avec VBA, consultez la page d'explication de Slipstick . Vous trouverez des informations sur:

• paramètres de sécurité macro;
• où mettre le code (vous pouvez utiliser un module standard avec Insert | Module); et
• comment créer un bouton.

Selon cet article du forum Afficher les éléments répétés , il n'est pas possible de voir une liste des éléments répétés. Le message suggère que vous pouvez voir une quantité limitée d'informations utiles en créant une vue personnalisée qui affiche certains des champs de rappel.

Essayez de cliquer sur l'onglet Calendrier, sélectionnez Afficher et modifier la vue. Sélectionnez ensuite Liste. Cela semble afficher une liste de tous les rappels.