Raccourci ou macro pour changer le type de police dans Microsoft Outlook

Existe-t-il un raccourci clavier pour modifier la police dans Outlook sur Windows? Je dois constamment alterner entre Calibri et Courier pour des raisons techniques et cliquer sur la boîte de dialogue des polices à chaque fois devient très fastidieux. Je sais que je peux utiliser Ctrl + Espace pour changer quoi que ce soit à la police par défaut (Calibri).

S'il n'y a pas de raccourci, quelqu'un pourrait-il m'aider à créer une macro pour basculer les polices? J'imagine que je peux attribuer n'importe quel raccourci à une macro?

(La réponse de techie007 n'a pas fonctionné pour moi dans Outlook 2010)

Cette macro (adaptée de http://www.slipstick.com/developer/word-macro-apply-formatting-outlook-email/ ) permet:

Sub SetCodeFont()
    Dim objItem As Object
    Dim objInsp As Outlook.Inspector

    Dim objWord As Word.Application
    Dim objDoc As Word.Document
    Dim objSel As Word.Selection
    On Error Resume Next

    Set objItem = Application.ActiveInspector.CurrentItem
    If Not objItem Is Nothing Then
        If objItem.Class = olMail Then
            Set objInsp = objItem.GetInspector
            If objInsp.EditorType = olEditorWord Then
                Set objDoc = objInsp.WordEditor
                Set objWord = objDoc.Application
                Set objSel = objWord.Selection
                objSel.Font.Name = "Consolas"
            End If
        End If
    End If

    Set objItem = Nothing
    Set objWord = Nothing
    Set objSel = Nothing
    Set objInsp = Nothing
End Sub

Ensuite, dans l'éditeur VBA, accédez à Tools > Referenceset sélectionnez Microsoft Word 14.0 Object Library.

Maintenant, pour créer un raccourci clavier pour une macro, ajoutez-le à votre barre d'outils d'accès rapide comme suit:

1. Ouvrez un nouveau message électronique
2. Cliquez sur la petite flèche déroulante de la barre d'outils d'accès rapide (généralement située en haut de la fenêtre) et sélectionnez "Plus de commandes ..."

3. La boîte de dialogue Options Outlook s'ouvre, puis sélectionnez "Macros" dans la liste déroulante "Choisir les commandes à partir de:"

4. Sélectionnez la macro SetCodeFont dans la liste et appuyez sur "Ajouter >>"
5. Le bouton macro apparaît maintenant dans la barre d'outils d'accès rapide

Pour exécuter la macro, mettez du texte en surbrillance et appuyez sur l' Alt + <Num>emplacement <Num>de la macro dans votre barre d'outils d'accès rapide. Par exemple, si la macro est le premier bouton de la barre d'outils, utilisez Alt + 1pour l'invoquer.

Pour information, il est la séquence de touches pour focaliser le sélecteur de la police: Alt, H, F,F