Un lecteur réseau mappé peut-il être reconnecté à partir de la ligne de commande?

Au quotidien, je me retrouve dans l'invite de commande Windows devant accéder à un lecteur réseau mappé mais déconnecté. Je n'ai pas encore trouvé de commande qui reconnectera ce disque sans démapper et remapper (ce qui conduit à un jeu de devinettes de mot de passe, car je ne possède pas ces ordinateurs). Je voudrais également pouvoir l'écrire afin que chaque soir le disque soit reconnecté s'il est déconnecté d'une manière ou d'une autre.

La solution la plus rapide que j'ai actuellement consiste à:

1. Tapez " start." pour ouvrir l'explorateur,
2. Alt- Dpour focaliser la barre d'adresse,
3. tapez la lettre de lecteur que je veux et appuyez sur Entrée, et attendez qu'elle affiche le contenu du lecteur,
4. puis enfin, fermez l'explorateur et revenez à l'invite de commande.

Je sais que c'est un inconvénient mineur, mais je le fais souvent via une connexion lente VNC ou PCAnywhere où faire quoi que ce soit via GUI est horrible, donc je me demande simplement s'il y a une meilleure solution.

Peut-être essayer pushd \\server\share?

Je dois démarrer Windows 7 avant de pouvoir exécuter le programme VPN qui me connecte aux lecteurs réseau de l'entreprise. Par conséquent, mes lecteurs réseau ne se reconnectent pas automatiquement, seuls les ouvrir dans l'Explorateur Windows les reconnecte.

J'ai créé un petit fichier de commandes pour démarrer le VPN, reconnecter les lecteurs réseau et démarrer certaines applications que j'utilise toujours.

Dans mon fichier batch, j'ai les éléments suivants:

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

La Taskkill /fi "windowtitle eq"commande est sensible à la casse!

créer un fichier batch (refreshletters.cmd) avec ces commandes

( ceux-ci ne fonctionneront qu'à l'intérieur d'un fichier batch )

Testé sur Win7 et XP pour actualiser les lettres de pilote «Déconnecté» et «Non disponible» dans une fenêtre de console (ligne de commande).

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

C'est probablement une question stupide, mais en supposant que votre lecteur "déconnecté" est H :, avez-vous essayé de passer directement au lecteur?

Cela fonctionne pour moi sous XPSP3:

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

Je sais que vous avez dit que "l'utilisation nette" ne fonctionnait pas pour vous - mais voici ce que vous pourriez essayer.

Exécutez un fichier de commandes avec l'option net use / DELETE pour supprimer les connexions existantes / persistantes. Vous pouvez ensuite utiliser net use avec l'option / SAVECRED pour réutiliser les informations d'identification passowd utilisées lors de la dernière connexion réussie. Je ne sais pas si cela résoudra votre problème, mais cela vaut la peine d'être étudié.

J'ai le même problème avec plusieurs connexions, et c'est intermittent. Lorsque je redémarre l'ordinateur, la connexion est parfois «bonne» et parfois non. Je n'ai pas le problème de mot de passe car je suis sur un réseau local d'entreprise, mais j'ai toujours l'autre aspect du problème.

J'ai créé un fichier de commandes appelé ex.bat et l'ai stocké (avec bien d'autres choses) dans un répertoire \ util que j'ai mis dans mon chemin. Je peux taper "ex h:" et il exécutera l'Explorateur Windows et le configurera pour aller directement sur le lecteur h :. Voici le fichier batch:

start explorer /e,/select,%1

Cela fonctionne, avec beaucoup moins de touches. Ou si cela ne fonctionne pas au début, appuyez sur la touche Entrée pour ouvrir le dossier racine h: et afficher le contenu. Ou, tapez "ex h: \ sub" là où le sous-dossier "sub" existe.

Ce problème semble s'être aggravé récemment, peut-être en raison de l'un des correctifs de sécurité de Windows XP.

Une autre chose à essayer est côté serveur. Sur les serveurs Windows, la modification d'une clé de Registre est censée empêcher le serveur de déconnecter ses connexions lors d'un délai d'attente. Je le fais sur à peu près tous nos serveurs. Le fichier est:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

J'ai eu un problème similaire et j'ai découvert que je pouvais forcer une reconnexion avec un simple "dir x:" à partir de la ligne de commande (où X: était le lecteur mappé mais déconnecté.) Il s'agissait d'un système Server 2003 à des lecteurs mappés sur XP et Win7 des ordinateurs.

J'ai créé un fichier batch, wake_network_drives.bat, avec ces deux lignes:

    dir x:
    dir z:

et définissez une tâche planifiée pour l'exécuter tous les soirs avant le programme de sauvegarde qui échouait car les disques étaient parfois affichés comme déconnectés.

Tapez simplement:

NET USE H: \\server\share

(où H: est bien sûr votre lettre de lecteur)

Tapez 'NET /? UTILISER 'pour voir toutes les options que cette commande vous offre.

Si vous n'êtes pas opposé à conserver ces mots de passe en texte brut dans un lot, vous pouvez créer un script de suppression et de remappage, y compris les informations d'identification.

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

Je sais que cela ne répond pas à votre exigence de ne pas supprimer le partage, mais cela résout la racine du problème de devoir se souvenir des mots de passe.

Résumé TL; DR: utilisation net useetif exist

J'ai rencontré un problème connexe lors de la création d'un script de sauvegarde nocturne. Il devait vérifier si un ordinateur était allumé (en utilisant ping), envoyer un paquet magique pour l'allumer si nécessaire (en utilisant MC-WOL ), attendre que Windows démarre, puis établir une connexion à un partage SMB et l'attendre être présente.

Bien que les autres réponses ici soient excellentes, je ne voulais pas que des lettres de lecteur mappées apparaissent / disparaissent, ni déconnecter tout ce avec quoi l'utilisateur pourrait travailler, ni que les fenêtres de l'Explorateur clignotent. c.-à-d. Un objectif était zéro distraction des utilisateurs .

Voici un morceau de code qui peut vous être utile:

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

Si vous préférez, vous pouvez remplacer l'adresse IP ci-dessus par un nom d'hôte (par exemple server1).

net useest nécessaire dans le cas où aucune connexion existante n'est présente. Je suis tombé sur des cas d'angle où cela seul semblait insuffisant pour «réveiller» le partage (par exemple, s'il existait une connexion antérieure dans un état déconnecté). Je trouve la if existsdirective a un effet similaire que les alternatives mentionnées dans d' autres réponses (comme pushd, dir, Explorer, etc.), mais il semblait une approche plus légère.

La réponse de StanZ a fonctionné pour moi, mais je devais être en mesure de déterminer par programme tous les lecteurs mappés sans statut OK, car les utilisateurs de notre domaine obtiennent différents mappages de lecteurs. J'ai codé ici pour fonctionner comme une version autonome, qui s'exécute net useavant et après le code réel, afin que vous puissiez voir les résultats, mais vous n'avez qu'à copier la seule FORinstruction (trois lignes) dans votre code pour obtenir les résultats souhaités.

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: /superuser/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: /superuser//a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

Peut-être une vieille question, mais toujours d'actualité en 2017 et Windows 10, car les partages réseau ne sont souvent pas reconnectés ou attachés correctement par Windows pour différentes raisons. Sur la base de ce problème et de l'absence d'une véritable solution de travail praticable et complète, j'ai créé un projet Github qui contient une tâche de planificateur et un VBS qui résout le problème en essayant simplement de reconnecter les disques après la reprise ou la connexion s'ils ne sont pas connectés ou en ligne.

Le script est entièrement configurable et peut être configuré en fonction des besoins de l'utilisateur réel.

Chemin vers le projet Github