Comment configurer Firefox via un script?

Je cherche à configurer les paramètres de Firefox suivants via un script (VBS ou batch)

• Page d'accueil par défaut
• moteur de recherche par défaut
• désactiver la mise à jour automatique

Est-ce possible?

Vous pouvez le faire en créant ou en manipulant des fichiers de préférences de Mozilla avec votre langage de script préféré.

Pour obtenir une liste des préférences pouvant être définies via ces fichiers, consultez les Préférences de Mozilla et à propos de: la documentation de config , bien que celles qui correspondent à votre liste semblent être: -

• browser.startup.homepage (Page d'accueil par défaut)
• browser.search.defaultenginename (moteur de recherche par défaut)
• app.update.auto (activer / désactiver la mise à jour automatique)

Toutefois, en fonction de votre environnement, il peut être préférable d’envoyer les paramètres via un module complémentaire personnalisé (voir les commentaires XPI dans le bref guide des préférences de Mozilla ) ou via un objet de stratégie de groupe avec FirefoxADM ou similaire.

Vous pouvez remplacer les options du navigateur privé dans un fichier user.js du dossier Profils utilisateur. Je l'utilise souvent pour remplacer certaines options, par exemple le traitement en pipeline. Firefox doit être redémarré après avoir mis à jour le fichier user.js. Si le fichier user.js n'existe pas, vous devez en créer un.

copier / coller littéralement la partie de la réponse que je cherchais (gagner env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

ajouter

user_pref("browser.startup.homepage", "http://www.URL");

Mes tentatives de copie sur des machines distantes avec Get-Content / cat string.txt / "String" >> chemin, se sont terminées par l'insertion de déchets dans le prefs.jsfichier en raison des caractères d'échappement de la chaîne.

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Le fil est un peu vieux, mais je veux quand même partager ma solution. J'espère que ça aide quelqu'un. Nous avons eu un problème similaire et nous voulions ajouter les certificats de Windows Store à Firefox. J'ai donc créé un script pour le faire. Quoi qu'il en soit, vous pouvez le modifier selon vos besoins: Ajoutez ou supprimez simplement les lignes sur :: create cfg_file_name.cfg [...] et insérez ce dont vous avez besoin, par exemple pour démarrer la page d'accueil, etc. N'oubliez pas de placer le ^ avant le dernier), sinon cela ne fonctionnera pas! echo pref("browser.startup.homepage", "http://superuser.com"^);

Depuis la version 49, vous pouvez le faire comme ça:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit