script de surveillance pour les services de fenêtre

Je dois surveiller certains logiciels tiers exécutant plusieurs services sous Windows. Je veux simplement le configurer pour que je reçoive un courrier électronique si le service redémarre, échoue, etc.

Est-ce quelque chose qui peut être facilement scripté? Quelqu'un at-il quelque chose de fondamental pour cette tâche?

C'est un peu moche, mais vous pouvez probablement le modifier pour l'adapter à vos besoins. Configurez simplement une tâche planifiée pour appeler le script de temps en temps.

Dim ServiceDown
Dim Message

Function sGetServiceStatus(ByVal strServiceName)
    wbemImpersonationLevelImpersonate = 3
    wbemAuthenticationLevelPktPrivacy = 6

    Set objLocator = CreateObject("WbemScripting.SWbemLocator")
    Set objWMIService = objLocator.ConnectServer("localhost")

    objWMIService.Security_.ImpersonationLevel = wbemImpersonationLevelImpersonate
    objWMIService.Security_.AuthenticationLevel = wbemAuthenticationLevelPktPrivacy

    Set colListOfServices = objWMIService.ExecQuery("Select * from Win32_Service Where DisplayName ='"& strServiceName & "'")

    if(colListOfServices.Count=0) then
        sGetServiceStatus = ""
        Exit function
    end if

    For Each objItem in colListOfServices
        If objItem.DisplayName = strServiceName and objItem.State = "Running" Then
            sGetServiceStatus = objItem.State                       
            Exit Function
        else
            sGetServiceStatus = objItem.State
            ServiceDown = True
            Message = Message & vbcrlf & strServiceName
            Exit function
        End If
    Next

    sGetServiceStatus = ""
End Function

sGetServiceStatus("ISC BIND")
sGetServiceStatus("Apache2.2")
sGetServiceStatus("MySQL")

If ServiceDown Then     
    Set objMessage = CreateObject("CDO.Message") 
    objMessage.Subject = "Check Services" 
    objMessage.From = "admin@yourhost.com" 
    objMessage.To = "admin@yourhost.com" 
    objMessage.TextBody = "The following service(s) is/are down: " & Message
    objMessage.Send                 
End If