Comment contrôler le volume du système sous OS X avec un clavier sans contrôle multimédia?

J'utilise un clavier PC sous Mac OS. Je peux utiliser la barre de menus pour contrôler le volume, mais existe-t-il des raccourcis clavier que je peux utiliser pour modifier le volume du système?

Ou peut-être un simple script ou une solution que je peux installer pour pouvoir régler le volume à l'aide du clavier.

Vous pouvez acheter la version pro de Sizzling Keys . C'est un preference panequi vous permet de définir un raccourci clavier personnalisé pour modifier le volume du système, entre autres.

Vous pouvez également modifier le volume du système à l'aide d'AppleScript.

Ouvrez l'éditeur AppleScript et entrez

set volume output volume 100

Le volume est sur une échelle de 0 à 100. Vous pouvez soit définir une valeur absolue (par exemple 100 pour le volume complet), soit créer des scripts qui augmentent / diminuent, tels que les suivants:

set vol to output volume of (get volume settings)
if vol > 90 then # 100 max
    set volume output volume 100
else
    set volume output volume (vol + 10)
end if

Pour le volume bas:

set vol to output volume of (get volume settings)
if vol < 10 then # 0 is min
    set volume output volume 0
else
    set volume output volume (vol - 10)
end if

Si vous souhaitez reproduire le son de retour qui se produit normalement lorsque vous changez le volume, vous pouvez ajouter ce qui suit au script:

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

Vous pouvez enregistrer ces scripts en tant qu'applications ou les intégrer dans le menu Services à l' aide d'Automator en tant que service sans entrée. Vous pouvez définir des raccourcis clavier pour les services dans Préférences Système »Clavier» Raccourcis clavier »Services

Karabiner (anciennement KeyRemap4MacBook) peut remapper les touches de fonction pour contrôler le volume et a fonctionné de manière transparente pour moi jusqu'à présent. Dans le panneau de configuration, recherchez «F9 pour couper le son», etc.

J'ai emballé un ensemble de services et d'instructions AppleScript qui vous permettent de contrôler le volume du système et d'iTunes, ainsi que la lecture / pause et la prochaine / précédente sur n'importe quel clavier dans Lion.

http://gskinner.com/blog/archives/2011/10/media-keys-in-osx-for-any-keyboard.html

Vieux fil, mais la façon dont je l'ai résolu est via une seule ligne applescript basée sur d'autres réponses

Augmentez le volume de 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) + 10)'

Diminuer le volume de 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) - 10)'

En fait, j'ai fini par écrire un article de blog sur son utilisation avec l'application Alfred: http://arif.im/system-volume-control-using-alfred/

Les touches F1 à F12 du clavier du PC devraient faire la même chose. Je suppose que vous n'avez eu aucun problème à remplacer la touche "Windows" par la touche ⌘ . Si les touches F1 à F12 ne fonctionnent pas, accédez aux préférences système, clavier et souris, clavier et faites vos choix à partir de là, que vous utilisiez les touches F directement ou avec le qualificateur de touche fn. Cordialement Paul

Voici ma solution complète pour les raccourcis pour augmenter, diminuer et couper le volume. J'utilise l'application Spark pour lier des combinaisons de touches à ces scripts ( http://www.macupdate.com/app/mac/14352/spark ). Les scripts vérifient l'état muet actuel et le gèrent, afin d'éviter des problèmes étranges qui peuvent survenir si vous ne le contrôlez pas correctement.

Monter le son:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
end if
set vol to output volume of (get volume settings)
if vol > 95 then
    set volume output volume 100
else
    set volume output volume (vol + 5)
end if

do shell script "afplay /System/Library/Sounds/Pop.aiff"

Baisser le volume:

set vol to output muted of (get volume settings)
if (vol = true) then
    error number -128
else
    set vol to output volume of (get volume settings)
    if vol < 5 then # 0 is min
        set volume with output muted
    else
        set volume output volume (vol - 5)
    end if

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

end if

Activer / désactiver le son:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
else
    set volume with output muted
end if