Un problème avec la fonction moyenne

J'ai un problème très ennuyeux avec la fonction moyenne.

Je fais des moyennes où parfois je n'ai pas de données dans une colonne (colonne C dans l'image ci-dessous). Il écrit ensuite un 0 mais le considère toujours comme un nombre moyen qui n’est pas du tout pratique.

Est-il possible d’obtenir la moyenne de sorte que lorsqu’elle est 0, elle ne compte pas dans la moyenne. Sinon, toutes mes données sont fausses.

Merci de votre aide!!

Est-il possible que la moyenne pour que 0 soit exclue?

Utiliser AVERAGEIFou AVERAGEIFSau lieu de AVERAGE:

Pour exclure 0:

=AVERAGEIF(A1:A50,">0")

Pour exclure les cellules vides:

=AVERAGEIF(A1:A50,"<>""")

Pour exclure 0 et supprimer des cellules:

=AVERAGEIFS(A1:A50,A1:A50,">0",A1:A50,"<>""")

Remarque:

• AVERAGEIFet AVERAGEIFSont été introduits dans Excel 2007
• Pour les versions antérieures d'Excel, voir Une moyenne qui exclut les valeurs nulles.

Une moyenne qui exclut les valeurs nulles (Excel 2007 et 2010)

Veronica sait comment utiliser la AVERAGEfonction pour déterminer la moyenne d'une plage de valeurs. Elle aimerait toutefois que la moyenne soit déterminée en fonction des valeurs non nulles dans la plage.

La fonction de feuille de calcul la mieux adaptée à cette fin est à utiliser AVERAGEIF. Vous pouvez l'utiliser de cette manière:

=AVERAGEIF(A1:A50,">0")

Cette fonction n'inclut que dans la moyenne les cellules contenant des valeurs supérieures à zéro. Si vous souhaitez également exclure les cellules vides, vous devez utiliser la AVERAGEIFSfonction. Cette fonction diffère de AVERAGEIFpar le fait qu’elle vous permet de spécifier plusieurs critères indiquant les cellules à moyenner.

=AVERAGEIFS(A1:A50,A1:A50,">0",A1:A50,"<>""")

Bien sûr, si vous voulez aborder le problème "vieille école" (sans utiliser AVERAGEIFou AVERAGEIFS), vous pouvez procéder de plusieurs manières. La première consiste à se rappeler comment une moyenne est calculée. Il est défini comme la somme d'une plage de valeurs divisée par le nombre d'éléments de la plage. Ainsi, vous pouvez calculer la moyenne d'exclusion simplement en vous assurant que le dénominateur (le nombre que vous divisez par) n'inclut pas de valeur zéro. Par exemple:

=SUM(A1:A50)/COUNTIF(A1:A50,"<>0")

Cette approche utilise la COUNTIFfonction pour déterminer le nombre de cellules de la plage (A1:A50)qui ne contiennent pas zéro. Si cette plage contient non seulement des zéros mais également des cellules vides et que vous ne souhaitez pas que les cellules vides figurent dans le résultat, vous devez utiliser une formule plus complexe:

=SUM(A1:A50)/(COUNTIF(A1:A50,"<>0")-COUNTBLANK(A1:A50)- (COUNTA(A1:A50)-COUNT(A1:A50)))

La COUNTIFfonction compte les cellules qui ne sont pas explicitement évaluées à 0, mais elle compte les cellules vides et les cellules de texte. Le COUNTBLANKterme s'ajuste pour les cellules vides et la différence entre COUNTAet COUNTajuste le nombre total de cellules qui contiennent du texte.

Bien sûr, vous pouvez également utiliser une formule matricielle pour effectuer votre calcul:

=AVERAGE(IF(A1:A50<>0,A1:A50))

Rappelez - vous que les formules de tableau doivent être saisis en utilisant la combinaison Ctrl+ Shift+ Enter. Cette formule de tableau exclut également les blancs ou les cellules contenant du texte.

Dans l’ensemble, il est plus facile d’utiliser les fonctions AVERAGEIFou AVERAGEIFS.

Source Une moyenne qui exclut les valeurs nulles