Comment ouvrir le menu contextuel dans (MacOS) Finder avec le clavier

Je suis sûr que la plupart d'entre nous aiment faire les choses le plus efficacement possible et nous sommes donc un tas de drogués au clavier.

Avec un fichier (ou un groupe de fichiers) en surbrillance, existe-t-il un moyen d'ouvrir le menu contextuel (équivalent d'un clic droit) avec le clavier?

Réponse courte: non.

La plupart des éléments du menu contextuel du Finder sont déjà accessibles via la barre de menus et tout élément de la barre de menus est un jeu équitable pour un raccourci clavier personnalisé dans les Préférences Système (Préférences Système> Clavier> Raccourcis clavier> Raccourcis d'application). Vous pouvez attribuer des raccourcis clavier pour la plupart des applications (Firefox exclus) dans ce panneau et qui inclut le Finder. S'il ne prend pas effet immédiatement, relancez simplement le Finder.

Objets proxy Quicksilver , en particulier l'objet proxy "Sélection actuelle".

Cela vous permettra d'invoquer Quicksilver avec tous les éléments que vous avez sélectionnés dans le Finder comme étant votre objet.

J'ai un déclencheur (le mien est réglé sur ⌘ + Maj + Espace) configuré pour obtenir tous les éléments actuellement sélectionnés dans le Finder. Le résultat final est que je peux effectuer des actions sur les éléments actuellement sélectionnés dans le Finder avec, comme, trois touches. La plupart des choses que je peux faire pour les éléments se trouvent dans le menu contextuel, mais pas toutes, si je me souviens bien. Pourtant, assez pratique.

Pas tout à fait exactement le menu contextuel, très proche cependant. Si vous utilisez les commandes d'accès universel, vous pouvez accéder au menu du bouton Tâche dans la barre de boutons.

Appuyez sur Ctrl-F5 pour mettre le focus sur la barre de boutons. Appuyez sur tab jusqu'à ce que le bouton Tâche soit en surbrillance, appuyez sur espace pour l'ouvrir, utilisez les flèches pour faire votre sélection.

Notez que vous devrez peut-être activer l'accès universel et que vous pouvez modifier le raccourci control-F5 dans le préfiltre Clavier. De plus, le nom du bouton peut être légèrement différent en anglais (je cours en néerlandais et je ne peux pas être dérangé pour changer de langue pour vérifier la traduction exacte).

Cela répond à la question plus spécifique de votre commentaire à votre question d'origine. Cela aurait probablement pu être une nouvelle question car elle est beaucoup plus spécifique.

Pour définir le «Color Label» des fichiers actuellement sélectionnés, vous pouvez combiner un programme AppleScript (ou un programme shell qui utilise osascript ) avec n'importe laquelle de la multitude d'applications de «lanceur» (Quicksilver, FastScripts, etc.) qui peuvent exécuter AppleScript programmes (ou programmes shell) basés sur une combinaison de touches de raccourci.

Pour l'un des scripts ci-dessous, collez-les dans Script Editor / AppleScript Editor et enregistrez-les au format «script» (ou dans le format que votre lanceur choisi utilise). L'endroit habituel pour de tels scripts enregistrés serait ~ / Library / Scripts / Applications / Finder, mais, selon votre lanceur, vous pouvez utiliser d'autres emplacements.

Voici une version simple que vous pouvez coder en dur sur n'importe laquelle des étiquettes:

on run
    tell application "Finder"
        repeat with anItem in (get selection)
            (*
             * 0 - none
             * 1 - Orange
             * 2 - Red
             * 3 - Yellow
             * 4 - Blue
             * 5 - Purple
             * 6 - Green
             * 7 - Gray
             *)
            set label index of anItem to 4
        end repeat
    end tell
end run

Si vous n'avez que quelques étiquettes que vous utilisez, vous pouvez enregistrer quelques copies de cela et lier une clé à chaque copie.

Voici une version qui vous demande toujours quelle étiquette appliquer:

on run
    tell application "Finder" to set selectedItems to selection
    if length of selectedItems is 0 then
        display dialog "Select some items in Finder before running this program." with title "Apply Finder Label to Selected Items" buttons {"OK"} default button {"OK"}
        return
    end if

    set labels to prependIndicies(getLabelNames())
    set default to first item of labels
    set labelIndex to choose from list labels default items default with prompt "Choose label to apply to selected items" without empty selection allowed and multiple selections allowed
    if labelIndex is false then return
    set labelIndex to (first word of first item of labelIndex) as number

    tell application "Finder"
        repeat with anItem in selectedItems
            set label index of anItem to labelIndex
        end repeat
    end tell
end run

to getLabelNames()
    set labelNames to {"Orange", "Red", "Yellow", "Blue", "Purple", "Green", "Gray"}

    set useCustomLabelNames to true -- change to false if this is too slow or does not work for you
    if useCustomLabelNames then
        set cmds to {}
        repeat with i from 1 to 7
            set end of cmds to "defaults read com.apple.Labels Label_Name_" & (8 - i) & " || echo " & quoted form of item i of labelNames
        end repeat
        set text item delimiters to {";"}
        set labelNames to paragraphs of (do shell script (cmds as text))
    end if
end getLabelNames

to prependIndicies(theList)
    repeat with i from 1 to length of theList
        set item i of theList to (i as text) & " - " & (item i of theList)
    end repeat
    {"0 - none"} & theList
end prependIndicies

Lorsque la boîte de dialogue apparaît, tapez l'un de 0 à 7 pour sélectionner une étiquette, puis appuyez sur Retour pour l'appliquer aux éléments sélectionnés dans le Finder.

Le menu contextuel ne peut être ouvert principalement que par un clic droit de la souris. Mais dans les paramètres d'accès universel dans les préférences système, nous pouvons contrôler les touches de la souris en utilisant le pavé numérique du clavier. Lorsqu'il est activé, un clic droit de la souris peut alors être réalisé Ctrl-5sur un clavier avec un pavé numérique ou Fn-Ctrl-Isur un ordinateur portable. Cela vous permettra de «cliquer avec le bouton droit» sur votre mot.

Accédez à Préférences système -> Accès universel -> Souris -> Activer les touches de la souris (ON)

Trouvé sur: /programming//a/11238186/1919382

Je ne connais pas de moyen d'ouvrir le menu contextuel de la sélection actuelle (ce que je pense que vous voulez vraiment) mais vous pouvez "cliquer avec le bouton droit" quoi que ce soit sous le pointeur de la souris avec uniquement le clavier.

Activation ou désactivation des touches rémanentes et des touches de la souris

Raccourcis pour les touches de la souris

• Activez les touches de la souris.
  • Dans les Préférences Système, recherchez les «touches de la souris» et activez-le.
    • Vous pouvez également choisir d'avoir cinq pressions sur les touches de la souris à bascule Option.
• Positionnez le curseur de la souris.
• Maintenez le contrôle.
• Appuyez et relâchez la touche 5 du clavier (ou Fn + I (pas L, celle entre U et O)).
• Relâchez le contrôle.

Mais cela dépend du positionnement correct du pointeur de la souris. Si vous avez sélectionné les fichiers dans le Finder sans utiliser la souris, le pointeur de la souris se trouvera probablement quelque part complètement sans rapport avec votre tâche du Finder .