Fractionner les commandes longues en plusieurs lignes via le fichier de commandes Windows

Comment puis-je diviser de longues commandes sur plusieurs lignes dans un fichier de commandes?

Vous pouvez rompre les longues lignes avec le curseur ^tant que vous vous souvenez que le curseur et la nouvelle ligne qui le suit sont complètement supprimés. Donc, s'il doit y avoir un espace où vous rompez la ligne, incluez un espace. ( Plus d'informations ci-dessous. )

Exemple:

copy file1.txt file2.txt

serait écrit comme suit:

copy file1.txt^
 file2.txt

La règle pour le curseur est:

Un signe d'insertion à la fin de la ligne ajoute la ligne suivante, le premier caractère de la ligne ajoutée sera échappé.

Vous pouvez utiliser le curseur plusieurs fois, mais la ligne complète ne doit pas dépasser la longueur de ligne maximale de ~ 8 192 caractères (Windows XP, Windows Vista et Windows 7).

echo Test1
echo one ^
two ^
three ^
four^
*
--- Output ---
Test1
one two three four*

echo Test2
echo one & echo two
--- Output ---
Test2
one
two

echo Test3
echo one & ^
echo two
--- Output ---
Test3
one
two

echo Test4
echo one ^
& echo two
--- Output ---
Test4
one & echo two

Pour supprimer l'échappement du caractère suivant, vous pouvez utiliser une redirection.

La redirection doit être juste avant le signe d'insertion. Mais il existe une curiosité avec redirection devant le curseur.

Si vous placez un jeton sur le curseur, le jeton est supprimé.

echo Test5
echo one <nul ^
& echo two
--- Output ---
Test5
one
two


echo Test6
echo one <nul ThisTokenIsLost^
& echo two
--- Output ---
Test6
one
two

Et il est également possible d' incorporer des sauts de ligne dans la chaîne:

setlocal EnableDelayedExpansion
set text=This creates ^

a line feed
echo Test7: %text%
echo Test8: !text!
--- Output ---
Test7: This creates
Test8: This creates
a line feed

La ligne vide est importante pour le succès. Cela ne fonctionne qu'avec une expansion retardée, sinon le reste de la ligne est ignoré après le saut de ligne.

Cela fonctionne, car le signe d'insertion à la fin de la ligne ignore le saut de ligne suivant et échappe au caractère suivant, même si le caractère suivant est également un saut de ligne (les retours chariot sont toujours ignorés dans cette phase).

(Il s'agit essentiellement d'une réécriture de la réponse de Wayne, mais avec la confusion autour du curseur dissipée. Je l'ai donc posté en CW. Je n'ai pas peur de modifier les réponses, mais les réécrire complètement semble inapproprié.)

Vous pouvez rompre les longues lignes avec le caret ( ^), rappelez-vous simplement que le caret et la nouvelle ligne qui le suit sont entièrement supprimés de la commande, donc si vous le placez là où un espace serait nécessaire (comme entre les paramètres), assurez-vous d'inclure également l'espace (soit avant la^ , soit au début de la ligne suivante - ce dernier choix peut aider à rendre plus clair que c'est une continuation).

Exemples: (tous testés sur Windows XP et Windows 7)

xcopy file1.txt file2.txt

peut s'écrire:

xcopy^
 file1.txt^
 file2.txt

ou

xcopy ^
file1.txt ^
file2.txt

ou même

xc^
opy ^
file1.txt ^
file2.txt

(Ce dernier fonctionne car il n'y a pas d'espaces entre le xcet le ^, et pas d'espaces au début de la ligne suivante. Ainsi, lorsque vous supprimez le ^et la nouvelle ligne, vous obtenez ...xcopy )

Pour la lisibilité et la raison, il est probablement préférable de ne briser qu'entre les paramètres (assurez-vous d'inclure l'espace).

Assurez-vous que ce ^n'est pas la dernière chose dans un fichier de commandes, car il semble y avoir un problème majeur avec cela .

Plusieurs commandes peuvent être mises entre parenthèses et réparties sur de nombreuses lignes; donc quelque chose comme ça echo hi && echo hellopeut être mis comme ceci:

( echo hi
  echo hello )

Les variables peuvent également aider:

set AFILEPATH="C:\SOME\LONG\PATH\TO\A\FILE"
if exist %AFILEPATH% (
  start "" /b %AFILEPATH% -option C:\PATH\TO\SETTING...
) else (
...

J'ai également remarqué avec carets ( ^) que les ifconditionnelles ne les aimaient à suivre que si un espace était présent:

if exist ^

Il semble cependant que le fractionnement au milieu des valeurs d'une boucle for ne nécessite pas de signe d'insertion (et en fait, essayer d'en utiliser un sera considéré comme une erreur de syntaxe). Par exemple,

for %n in (hello
bye) do echo %n

Notez qu'aucun espace n'est même nécessaire après bonjour ou avant au revoir.