TSQL - Comment utiliser GO à l'intérieur d'un bloc BEGIN .. END?

Je génère un script pour migrer automatiquement les modifications de plusieurs bases de données de développement vers la préparation / production. Fondamentalement, cela prend un tas de scripts de changement et les fusionne en un seul script, enveloppant chaque script dans une IF whatever BEGIN ... ENDinstruction.

Cependant, certains scripts nécessitent une GOinstruction afin que, par exemple, l'analyseur SQL connaisse une nouvelle colonne après sa création.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Cependant, une fois que j'enroule cela dans un IFbloc:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Il échoue parce que j'envoie un BEGINsans correspondance END. Cependant, si je supprime le, GOil se plaint à nouveau d'une colonne inconnue.

Existe-t-il un moyen de créer et de mettre à jour la même colonne dans un seul IFbloc?

J'ai eu le même problème et j'ai finalement réussi à le résoudre en utilisant SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO n'est pas SQL - c'est simplement un séparateur de lots utilisé dans certains outils MS SQL.

Si vous ne l'utilisez pas, vous devez vous assurer que les instructions sont exécutées séparément - soit dans différents lots ou en utilisant SQL dynamique pour la population (merci @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Vous pouvez essayer de sp_executesqldiviser le contenu entre chaque GOinstruction en une chaîne distincte à exécuter, comme illustré dans l'exemple ci-dessous. En outre, il existe une variable @statementNo pour suivre quelle instruction est exécutée pour un débogage facile là où une exception s'est produite. Les numéros de ligne seront relatifs au début du numéro de relevé pertinent qui a causé l'erreur.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Vous pouvez également facilement exécuter des instructions multilignes, comme illustré dans l'exemple ci-dessus, en les entourant simplement de guillemets simples ( '). N'oubliez pas d'échapper les guillemets simples contenus dans la chaîne avec un guillemet simple double ( '') lors de la génération des scripts.

J'ai finalement réussi à le faire fonctionner en remplaçant chaque instance de GOsur sa propre ligne par

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Ceci est grandement préférable à l'encapsulation de chaque groupe d'instructions dans une chaîne, mais c'est encore loin d'être idéal. Si quelqu'un trouve une meilleure solution, postez-la et je l'accepterai à la place.

Vous pouvez placer les instructions dans BEGIN et END au lieu de GO entre

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Testé sur la base de données Northwind)

Edit: (probablement testé sur SQL2012)

Vous pouvez essayer cette solution:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

J'ai utilisé RAISERRORdans le passé pour cela

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Vous pouvez incorporer des instructions GOTOet LABELpour sauter le code, laissant ainsi les GOmots - clés intacts.