Quelle est la meilleure façon de créer une sous-chaîne dans un fichier de commandes?

192

Je souhaite obtenir le nom du fichier de commandes en cours d'exécution sans l'extension de fichier.

Grâce à ce lien , j'ai le nom du fichier avec l'extension ... mais quelle est la meilleure façon de faire une sous-chaîne dans un fichier batch?

Ou existe-t-il un autre moyen d'obtenir le nom du fichier sans l'extension?

Il est prudent de supposer des extensions de 3 lettres dans ce scénario.

batch-file substring

— JosephStyons
source

398

Eh bien, pour obtenir simplement le nom de fichier de votre lot, le moyen le plus simple serait d'utiliser %~n0.

@echo %~n0

affichera le nom (sans l'extension) du fichier de commandes en cours d'exécution (sauf s'il est exécuté dans un sous-programme appelé par call). La liste complète de ces substitutions «spéciales» pour les noms de chemin peut être trouvée avec help for, à la toute fin de l'aide:

De plus, la substitution des références de variable FOR a été améliorée. Vous pouvez maintenant utiliser la syntaxe facultative suivante:

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

Les modificateurs peuvent être combinés pour obtenir des résultats composés:

%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only

Pour répondre précisément à votre question, cependant: les sous-chaînes sont effectuées en utilisant la :~start,lengthnotation:

%var:~10,5%

va extraire 5 caractères de la position 10 dans la variable d'environnement %var%.

REMARQUE: L'index des chaînes est basé sur zéro, donc le premier caractère est à la position 0, le second à 1, etc.

Pour obtenir des variables sous - chaînes d'arguments tels que %0, %1, etc. , vous devez les assigner à une variable d'environnement normal en utilisant d' setabord:

:: Does not work:
@echo %1:~10,5

:: Assign argument to local variable first:
set var=%1
@echo %var:~10,5%

La syntaxe est encore plus puissante:

%var:~-7% extrait les 7 derniers caractères de %var%
%var:~0,-4%extrait tous les caractères sauf les quatre derniers qui vous débarrasseraient également de l'extension de fichier (en supposant trois caractères après le point [ .]).

Voir help setpour plus de détails sur cette syntaxe.

— Joey
source

L'extraction de sous-chaîne ne fonctionne pas non plus avec les variables de boucle FOR, vous devrez donc faire comme suit (\ r \ n dans le code signifie des sauts de ligne car SO ne semble pas autoriser les sauts de ligne dans les commentaires):setlocal ENABLEDELAYEDEXPANSION \r\n for /f %%s in ('set') do ( \r\n set tmp=%%s \r\n echo !tmp:~-3! \r\n )

— Fr0sT

@ Fr0sT pourquoi devez-vous faire cela pour les FORboucles?

— Bob

@Adrian pourquoi pas? FORest une construction fondamentale dans les fichiers batch effectuant un très grand nombre de tâches diverses. Btw, il existe un autre moyen de faire face à la tâche en utilisant un sous-programme, c'estfor /f %%s in ('set') do call :DoSmth "%%s" \r\n ... \r\n :DoSmth \r\n set var=%1 \r\n echo %var:~1,3%

— Fr0sT

en utilisant le serveur Windows 12 R2,% date% ressemble au 21/05/18 (culture informatique); la bonne chaîne est: %date:~0,2%%date:~3,2%%date:~6,4%%time:~0,2%%time:~3,2%%time:~6,2%

— Phate01

@ Phate01, ne l'utilisez pas %date%pour construire une date dans un certain format. Le format est spécifique à la culture de l'utilisateur et peut changer. Utilisez plutôt WMI pour obtenir la date et l'heure dans un format utile qui ne dépend pas des paramètres de l'utilisateur. Je ne sais pas non plus ce que fait ce commentaire ici, car cette question ne portait pas sur la date ou l'heure.

— Joey

Bien expliqué ci-dessus!

Pour tous ceux qui peuvent souffrir comme moi pour que cela fonctionne dans un Windows localisé (le mien est XP en slovaque), vous pouvez essayer de remplacer le %par un!

Alors:

SET TEXT=Hello World
SET SUBSTRING=!TEXT:~3,5!
ECHO !SUBSTRING!

— BrandonSk
source

Notez que cela ne fonctionnera qu'après la setlocal ENABLEDELAYEDEXPANSIONcommande

— Fr0sT

Comme information supplémentaire à la réponse de Joey, qui n'est pas décrite dans l'aide de set /?ni for /?.

%~0se développe au nom du propre lot, exactement comme il a été tapé.
Donc, si vous démarrez votre lot, il sera développé comme

%~0   - mYbAtCh
%~n0  - mybatch
%~nx0 - mybatch.bat

Mais il y a une exception, l'expansion dans un sous-programme peut échouer

echo main- %~0
call :myFunction
exit /b

:myFunction
echo func - %~0
echo func - %~n0
exit /b

Cela se traduit par

main - myBatch
Func - :myFunction
func - mybatch

Dans une fonction se %~0développe toujours au nom de la fonction, pas du fichier de commandes.
Mais si vous utilisez au moins un modificateur, il affichera à nouveau le nom du fichier!

— jeb
source