Vim: Création de répertoires parents lors de l'enregistrement

Si j'invoque vim foo/bar/somefilemais foo/barn'existe pas déjà, Vim refuse de sauvegarder.

Je sais que je pourrais passer à un shell ou faire à :!mkdir foo/barpartir de Vim mais je suis paresseux :) Y a-t-il un moyen de faire en sorte que Vim fasse cela automatiquement quand il enregistre le tampon?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Notez les conditions: expand("<afile>")!~#'^\w\+:/'empêchera vim de créer des répertoires pour des fichiers comme ftp://*et !isdirectoryévitera un appel coûteux à mkdir.

Mise à jour : une solution légèrement meilleure qui vérifie également les buftype non vides et utilise mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Sur la base des suggestions de ma question, voici ce que j'ai obtenu:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Ceci définit la :Wcommande. Idéalement, je voudrais avoir tous :w!, :wq, :wq!, :walletc. fonctionnent de la même, mais je ne sais pas s'il est possible sans fondamentalement les réimplémentant toutes avec des fonctions personnalisées.

J'ai ajouté ceci à mon ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Si j'ai besoin de créer le répertoire dans :mk.lequel je suis, je tape et il le remplace par "! Mkdir -p / chemin / vers / mon / fichier /" et me permet de revoir la commande avant de l'invoquer.

J'ai fait :saveas!créer le répertoire s'il manquait: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Ce code vous demandera de créer le répertoire avec :w, ou simplement de le faire avec :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Je pense que j'ai réussi à le faire en trois lignes, combinant ce que les autres disent sur cette réponse.

Cela semble faire l'affaire:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Il tente de créer le dossier automatiquement lors de l'enregistrement d'un tampon. Si quelque chose de mauvais se produit (c'est-à-dire des problèmes d'autorisation), il se fermera et laissera l'écriture du fichier échouer.

Si quelqu'un voit des défauts évidents, veuillez poster un commentaire. Je ne connais pas très bien le vimscript.

EDIT: Notes grâce à ZyX

• Cela ne fonctionnera pas si vos dossiers ont des espaces dessus (apparemment, ils ne sont pas correctement échappés ou quelque chose du genre)
• Ou si vous créez des pseudo fichiers.
• Ou si vous achetez votre vimrc.
• Mais fils, c'est court.