Redirection de la sortie à partir d'un fichier batch

Je crée un fichier batch avec quelques commandes simples pour collecter des informations à partir d'un système. Le fichier de commandes contient des commandes pour obtenir l'heure, les informations IP, les utilisateurs, etc.

J'ai assemblé toutes les commandes dans un fichier de commandes, et il s'exécute, mais je voudrais que le fichier de commandes, lorsqu'il est exécuté, affiche les résultats dans un fichier texte (journal). Y a-t-il une commande que je peux ajouter au lot qui le ferait?

Gardez à l'esprit que je ne veux pas exécuter le lot à partir de cmd, puis rediriger la sortie; Je souhaite rediriger la sortie depuis l'intérieur du lot, si cela est possible.

La manière naïve simple qui est lente car elle ouvre et positionne le pointeur de fichier plusieurs fois vers la fin du fichier.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Un meilleur moyen - plus facile à écrire et plus rapide car le fichier n'est ouvert et positionné qu'une seule fois.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Un autre moyen efficace et rapide qui n'ouvre et ne positionne le fichier qu'une seule fois

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Modifier 17/04/2020

De temps en temps, vous souhaiterez peut-être écrire à plusieurs reprises dans deux fichiers ou plus. Vous pouvez également souhaiter différents messages à l'écran. Il est toujours possible de le faire efficacement en redirigeant vers des poignées non définies en dehors d'un bloc ou d'un sous-programme entre parenthèses, puis en utilisant la &notation pour référencer les fichiers déjà ouverts.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

J'ai choisi d'utiliser les poignées 9 et 8 dans l'ordre inverse, car cette méthode est plus susceptible d'éviter une redirection permanente potentielle en raison d'un défaut de conception de l'implémentation de la redirection Microsoft lors de l'exécution de plusieurs redirections sur la même commande. C'est très peu probable, mais même cette approche pourrait exposer le bogue si vous essayez assez fort. Si vous organisez la redirection, vous êtes assuré d'éviter le problème.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

si vous voulez rediriger les flux out et err

dir >> a.txt 2>&1

Je sais que c'est un article plus ancien, mais quelqu'un tombera dessus dans une recherche Google et il semble également que certaines questions posées par le PO dans les commentaires n'aient pas été spécifiquement traitées. Aussi, allez-y doucement car c'est ma première réponse publiée sur SO. :)

Pour rediriger la sortie vers un fichier en utilisant un nom de fichier généré dynamiquement, mon approche go-to (read: quick & dirty) est la deuxième solution proposée par @dbenham. Par exemple, ceci:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Créera un fichier comme ce que vous voyez dans cette capture d'écran du fichier dans le répertoire cible

Cela contiendra cette sortie:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Gardez également à l'esprit que cette solution dépend des paramètres régionaux, alors faites attention à la manière et au moment de l'utiliser.

echo some output >"your logfile"

ou

(
 echo some output
 echo more output
)>"Your logfile"

devrait remplir la facture.

Si vous voulez APPENDla sortie, utilisez à la >>place de >. >va démarrer un nouveau fichier journal.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Il existe un petit programme sympa que vous pouvez utiliser pour rediriger la sortie vers un fichier et la console

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Ajoutez ces deux lignes en haut de votre fichier de commandes, tous les stdout et stderr après seront redirigés vers log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

J'ai utilisé la commande ci-dessus dans mon fichier de commandes et cela fonctionne. Dans le fichier journal, il montre les résultats de ma commande.

Cela peut échouer dans le cas de caractères «toxiques» dans l'entrée. Considérer une entrée comme thisIsAnIn ^^^^ put est un bon moyen de comprendre ce qui se passe. Bien sûr, il existe une règle selon laquelle une chaîne d'entrée DOIT être entre guillemets doubles, mais j'ai le sentiment que cette règle n'est une règle valide que si la signification de l'entrée est un emplacement sur une partition NTFS (peut-être que c'est une règle pour les URL I suis pas sûr). Mais ce n'est pas une règle pour une chaîne d'entrée arbitraire bien sûr (c'est "une bonne pratique" mais vous ne pouvez pas compter avec).

L'ajout des lignes suivantes au bas de votre fichier de commandes récupérera tout comme affiché dans la fenêtre CMD et l'exportera dans un fichier texte:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Il effectue essentiellement une sélection de tout -> copier dans le presse - papiers -> coller dans un fichier texte .