Nous utilisons CMake pour générer les fichiers Visual Studio de nos sources dans notre SVN. Maintenant, mon outil nécessite que certains fichiers DLL se trouvent dans le même dossier que l'exécutable. Les fichiers DLL sont dans un dossier à côté de la source.

Comment puis-je changer mon CMakeLists.txtafin que le projet Visual Studio généré contienne déjà les fichiers DLL particuliers dans les dossiers release / debug ou les copie lors de la compilation?

J'utiliserais add_custom_commandpour y parvenir avec cmake -E copy_if_different.... Pour des informations complètes, exécutez

cmake --help-command add_custom_command
cmake -E

Donc, dans votre cas, si vous avez la structure de répertoires suivante:

/CMakeLists.txt
/src
/libs/test.dll

et votre cible CMake à laquelle la commande s'applique est MyTest, alors vous pouvez ajouter ce qui suit à votre CMakeLists.txt:

add_custom_command(TARGET MyTest POST_BUILD        # Adds a post-build event to MyTest
    COMMAND ${CMAKE_COMMAND} -E copy_if_different  # which executes "cmake - E copy_if_different..."
        "${PROJECT_SOURCE_DIR}/libs/test.dll"      # <--this is in-file
        $<TARGET_FILE_DIR:MyTest>)                 # <--this is out-file path

Si vous souhaitez simplement /libs/copier l'intégralité du contenu du répertoire, utilisez cmake -E copy_directory:

add_custom_command(TARGET MyTest POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_directory
        "${PROJECT_SOURCE_DIR}/libs"
        $<TARGET_FILE_DIR:MyTest>)

Si vous avez besoin de copier différentes DLL en fonction de la configuration (Release, Debug, par exemple), vous pouvez les avoir dans des sous-répertoires nommés avec la configuration correspondante:, /libs/Releaseet /libs/Debug. Vous devez ensuite injecter le type de configuration dans le chemin de la dll dans l' add_custom_commandappel, comme ceci:

add_custom_command(TARGET MyTest POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_directory
        "${PROJECT_SOURCE_DIR}/libs/$<CONFIGURATION>"
        $<TARGET_FILE_DIR:MyTest>)

J'ai mis ces lignes dans mon fichier CMakeLists.txt de niveau supérieur. Toutes les bibliothèques et exécutables compilés par CMake seront placés dans le niveau supérieur du répertoire de construction afin que les exécutables puissent trouver les bibliothèques et il est facile de tout exécuter.

set (CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})

Notez que cela ne résout pas le problème de l'OP de copier des binaires précompilés à partir du répertoire source du projet.

J'ai eu ce problème aujourd'hui lorsque j'ai essayé de créer une version Windows de mon programme. Et j'ai fini par faire des recherches moi-même puisque toutes ces réponses ne me satisfaisaient pas. Il y avait trois problèmes principaux:

• Je voulais que les versions de débogage soient liées aux versions de débogage des bibliothèques et que les versions de version soient liées aux versions de version des bibliothèques, respectivement.

• En plus de cela, je voulais que les versions correctes des fichiers DLL (Debug / Release) soient copiées dans les répertoires de sortie.

• Et je voulais réaliser tout cela sans écrire de scripts complexes et fragiles.

Après avoir parcouru certains manuels CMake et certains projets multiplateformes sur github, j'ai trouvé cette solution:

Déclarez votre bibliothèque comme cible avec l'attribut "IMPORTED", référencez son débogage et publiez les fichiers .lib et .dll.

add_library(sdl2 SHARED IMPORTED GLOBAL)
set_property(TARGET sdl2 PROPERTY IMPORTED_IMPLIB_RELEASE "${SDL_ROOT_PATH}/lib/SDL2.lib")
set_property(TARGET sdl2 PROPERTY IMPORTED_LOCATION_RELEASE "${SDL_ROOT_PATH}/bin/SDL2.dll")
set_property(TARGET sdl2 PROPERTY IMPORTED_IMPLIB_DEBUG "${SDL_ROOT_PATH}/lib/SDL2d.lib")
set_property(TARGET sdl2 PROPERTY IMPORTED_LOCATION_DEBUG "${SDL_ROOT_PATH}/bin/SDL2d.dll")

Associez cette cible à votre projet comme d'habitude

target_link_libraries(YourProg sdl2 ...)

Faites une étape de construction personnalisée pour copier le fichier dll vers sa destination s'il a été modifié d'une manière ou d'une autre depuis la construction précédente

add_custom_command ( TARGET YourProg POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_if_different
    $<TARGET_FILE:sdl2> $<TARGET_FILE_DIR:YourProg>
)

Un addendum à la réponse acceptée, ajouté en tant que réponse distincte afin d'obtenir le formatage du code:

Si vous construisez vos dll dans le même projet, elles seront généralement dans les répertoires Release, Debug, etc. Vous devrez utiliser les variables d'environnement Visual Studio pour les copier correctement. par exemple:

"${PROJECT_BINARY_DIR}/your_library/\$\(Configuration\)/your_library.dll"

pour la source et

"${CMAKE_CURRENT_BINARY_DIR}/\$\(Configuration\)/your_library.dll"

pour la destination. Notez la fuite!

Vous ne pouvez pas utiliser la variable CMake CMAKE_BUILD_TYPE pour la configuration car elle est résolue au moment de la génération du projet VS et sera toujours la valeur par défaut.

Vous pouvez également utiliser la commande find_library:

find_library(<some_var> NAMES <name_of_lib> PATHS "<path/to/lib>")

Avec un EXECUTABLE_PATH défini, par exemple:

set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)

vous pouvez déplacer les fichiers .dll dont votre exécutable a besoin, avec

file(COPY ${<some_var>}
    DESTINATION ${EXECUTABLE_OUTPUT_PATH})

Ceci est utile pour l'un d'eux

SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY
    ${PROJECT_SOURCE_DIR}/lib CACHE
    PATH "Directory where all the .lib files are dumped." FORCE)
SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY
    ${PROJECT_SOURCE_DIR}/bin CACHE
    PATH "Directory where .exe and .dll files are dumped." FORCE)

Vous devez probablement ajouter une cible personnalisée et la rendre dépendante de l'une de vos cibles exécutables.

Pour copier un fichier en utilisant la fonction ci-dessus, utilisez:

COMMAND ${CMAKE_PROGRAM} -E copy_if_different ${CMAKE_BINARY_DIR}/path/to/file.dll ${CMAKE_BINARY_DIR}/where/to/put/file.dll`

Je suis un débutant CMake, mais je voulais quand même partager mon expérience. Dans mon cas, j'avais besoin d'une copie post-installation pour que tous mes binaires soient inclus. Dans le cas d'un binaire tiers pouvant être importé dans CMake, ce qui suit fonctionne pour moi:

find_package( dependency REQUIRED )
if( MSVC ) 
    # If done properly and if the dependency has a correct config file, IMPORTED_LOCATION_RELEASE should be defined
    get_target_property( DEP_SHARED_LIB_PATH dependency IMPORTED_LOCATION_RELEASE )
    # Create a bin directory in the install folder
    add_custom_command(TARGET BGS POST_BUILD COMMAND ${CMAKE_COMMAND} -E make_directory  ${CMAKE_INSTALL_PREFIX}/bin/)
    # Copy the shared lib file
    add_custom_command(TARGET BGS POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy ${DEP_SHARED_LIB_PATH} ${CMAKE_INSTALL_PREFIX}/bin/)
endif()

De toute évidence, IMPORTED_LOCATION_RELEASE peut avoir des variantes en fonction de la manière dont la bibliothèque partagée a été construite / installée. Peut-être IMPORTED_LOCATION_DEBUG.

Il y a peut-être une meilleure façon d'obtenir ce nom de propriété, je ne sais pas.

Déplacement de fichiers pendant la construction à l'aide de install

J'ai eu ce problème en essayant de suivre le didacticiel officiel de CMake à l' étape 9 . C'était l'emplacement du fichier que je voulais déplacer:

src
 |_build
    |_Debug
       - `MathFunctions.dll`

C'était l'emplacement dans lequel je voulais que le fichier se trouve:

src
 |_build
    |_install
         |_bin
             - `MathFunctions.dll`

Étant donné que cette DLL a été générée en tant que bibliothèque partagée, tout ce que j'ai fait était d'inclure cette ligne dans le CMakeLists.txtsous- répertoire contenant le code source de la bibliothèquesrc/Mathfunctions/CMakeLists.txt

install(FILES ${PROJECT_BINARY_DIR}/$<CONFIG>/MathFunctions.dll
DESTINATION bin)

Grâce à vos réponses, j'ai pu réfléchir à celle-ci. Est juste une ligne, donc je pense que ça va. Le $<CONFIG>peut avoir deux valeurs Debug ou Release Selon la façon dont le projet est construit, comme la question d'origine l'exige.