Une des choses qui m'a frappé à propos de cette question est que le livret de cours indique que la valeur maximale est supérieure aux résultats du test, à savoir:
Maximum from test: 2001.27 kg/m3
Maximum from booklet: 2020 kg/m3
Mis à part le fait qu'il est difficile de voir d'où vient cette valeur, si les tests échouent sur cette base, le contractant risque de subir des retards, ce qui peut conduire à une réclamation pour le projet - ou à tout le moins à une situation potentiellement embarrassante. arguments. Lorsqu'une valeur supérieure acceptée pour le travail de l'entrepreneur est effectivement mesurée en laboratoire, il doit exister une raison valable. Examinons donc cela en examinant les données à l'aide de méthodes d'ajustement de courbe communément acceptées.
Cet article contient le code et les données qui sous-tendent cette procédure (pour ceux qui pourraient l’estimer utile), mais d’autres voudront peut-être ignorer les images et les conclusions.
Fichier de données
En utilisant GnuPlot , nous examinons: (1) la régression linéaire à l'aide de formes quadratiques et (2) l'interpolation entre des points à l'aide de splines cubiques. Le fichier de données pour ce processus, points.txt , est le suivant:
X Y X Y
8.4 1447.38 8.4 1447.38
10.2 1808.53 10.2 1808.53
12.3 2001.27 12.3 2001.27
14.6 1683.60 16.8 1524.81
16.8 1524.81
Les colonnes 1 et 2 sont les données fournies. Dans les colonnes 3 et 4, nous éliminons le point 4 en tant que valeur aberrante (ce n'est pas une valeur aberrante, mais aux fins de comparaison, considérons-le).
Fichier source GnuPlot
Le script gnuplot, density.gpl suit:
# gnuplot 4.6 patchlevel 4
# quadratic fit
f0(x) = a0*x**2+b0*x+c0
f1(x) = a1*x**2+b1*x+c1
# set formats
set output 'density.png'
set xlabel 'Moisture, %'
set ylabel 'Dry Density, kg/m3'
set yrange [1400:2200]
set key inside horizontal top right
set terminal pngcairo dashed # permits dashed lines
set terminal pngcairo size 640,480 enhanced font 'Verdana,10'
# pt 1 +, pt 2 X, pt 3 *, pt 4 box, pt 5 filled box, pt 6 circle, pt 7 filled circle
# lt 1 solid, 2 ---, 3 ..., 4 -.-, 5 -..-, 6 solid, 7 - - -
# color styles (for display)
set style line 1 lt 1 lc rgb 'black' lw 2 pt 7 ps 1.2
set style line 2 lt 1 lc rgb 'red' lw 2 pt 2 ps 1.2
set style line 3 lt 1 lc rgb 'blue' lw 2 pt 4 ps 1.2
set style line 4 lt 1 lc rgb 'green' lw 2 pt 6 ps 1.2
set style line 5 lt 1 lc rgb 'yellow' lw 2 pt 2 ps 1.2
# black styles (for printing)
set style line 10 lt 1 lc rgb 'black' lw 2 pt 7 ps 1.2
set style line 20 lt 2 lc rgb 'black' lw 2 pt 2 ps 1.2
set style line 30 lt 4 lc rgb 'black' lw 2 pt 4 ps 1.2
set style line 40 lt 5 lc rgb 'black' lw 2 pt 6 ps 1.2
set style line 50 lt 7 lc rgb 'black' lw 2 pt 2 ps 1.2
# fit data to forms
fit f0(x) 'points.txt' using 1:2 via a0,b0,c0
fit f1(x) 'points.txt' using 3:4 via a1,b1,c1
# plot the results
plot f0(x) with lines ls 2 smooth bezier title 'Quadratic', \
f1(x) with lines ls 3 smooth bezier title 'Quadratic w/o 4', \
'points.txt' using 3:4 with lines ls 4 title 'Cubic Spline w/o 4' smooth csplines, \
'points.txt' using 1:2 with lines ls 1 title 'Cubic Spline' smooth csplines, \
'points.txt' using 1:2 with points ls 1 notitle
Courbes humidité-densité
Nous lançons ensuite gnuplot à partir de la ligne de commande (système d’exploitation Linux Debian), l’affiche avec l’ affichage du programme ImageMagick et capturons toute la sortie dans le fichier stats.txt :
gnuplot density.gpl &> stats.txt && display density.png &
L'ensemble de courbes de densité d'humidité obtenu est le suivant:
Statistiques de densité d'humidité
A partir de stats.txt , la régression linéaire de tous les points (colonnes 1 et 2) donne:
degrees of freedom (FIT_NDF) : 2
rms of residuals (FIT_STDFIT) = sqrt(WSSR/ndf) : 121.785
variance of residuals (reduced chisquare) = WSSR/ndf : 14831.5
Final set of parameters Asymptotic Standard Error
======================= ==========================
a0 = -25.1676 +/- 7.493 (29.77%)
b0 = 633.079 +/- 189.8 (29.98%)
c0 = -2061.07 +/- 1147 (55.64%)
correlation matrix of the fit parameters:
a0 b0 c0
a0 1.000
b0 -0.995 1.000
c0 0.979 -0.994 1.000
Ces coefficients sont identiques à ceux du message de CoryKramer. Maintenant, le meilleur choix pour les colonnes 3 et 4 (avec la soi-disant valeur aberrante, point 4, écartée) devient:
degrees of freedom (FIT_NDF) : 1
rms of residuals (FIT_STDFIT) = sqrt(WSSR/ndf) : 4.71227
variance of residuals (reduced chisquare) = WSSR/ndf : 22.2055
Final set of parameters Asymptotic Standard Error
======================= ==========================
a1 = -29.4084 +/- 0.3123 (1.062%)
b1 = 750.537 +/- 8.016 (1.068%)
c1 = -2783.63 +/- 48.58 (1.745%)
correlation matrix of the fit parameters:
a1 b1 c1
a1 1.000
b1 -0.996 1.000
c1 0.982 -0.995 1.000
Soit dit en passant, il y a peu de différence dans les coefficients de corrélation entre les deux ensembles de données, mais il y a une très grande différence dans l'erreur type des coefficients. Cela pourrait signifier soit qu'il existe une valeur aberrante, qu'il y a trop peu de points de données ou que le modèle mathématique n'est pas satisfaisant.
Conclusion
Il est clair que la valeur maximale indiquée de 2020 kg/m3n'est pas supportée par les données. À partir de l'inspection des tracés d'humidité-densité, les valeurs maximales des différentes méthodes d'ajustement de courbe ne dépassent pas la valeur de test mesurée, seule la position de la teneur en humidité optimale change. Il est également clair que si un différend devait surgir sur un projet de construction, le contractant aurait un cas légitime.
Enfin, quelle courbe est la plus appropriée? Eh bien, la méthode de test de Proctor confère une grande fiabilité à chaque point de données, en ce sens que l’erreur de la méthode de test devrait être minime. Pour cette raison, seulement 5 valeurs de test sont requises. Par conséquent, il est logique d'interpoler entre ces points. Mon vote serait donc d'utiliser l'approche par spline cubique, y compris tous les points, plutôt que d'utiliser le modèle de régression linéaire.
