Est-il possible d'ajouter des modèles autres que # + BEGIN_ # + END_ à l'organisation-structure-template-alist?

J'ai remarqué que org-structure-template-alist a changé (j'utilise la version 9.2 du mode org) pour se développer automatiquement #+BEGIN_<some block tag> #+END_<some block tag>. Je me demande s'il est possible d'ajouter différents types de modèles. Par exemple un :PROPERTIES:<some properties>:END:modèle.

Est-il possible ou dois-je me tourner vers un autre package comme yasnippets?

MISE À JOUR:

Je n'ai pas remarqué que le mode Org 9.2 a changé le mécanisme d'expansion du modèle, où il org-structure-template-alistne s'applique qu'aux blocs définis par "#+BEGIN_"et "#+END_". Et l'entrée comme ("p" ":PROPERTIES:?:END:")n'est plus acceptée.

Comme mentionné dans le lien ci-dessus, d'autres modèles "complexes" peuvent être définis par fonction tempo-define-template, et org-tempo doit être chargé ( (require 'org-tempo)). En fait, les entrées de org-structure-template-alist sont converties en org-tempo-tagsvia tempo-define-templatepar org-tempoet par org-tempo-tagsdéfaut:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Pour votre cas, vous pouvez définir un modèle en:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

La réponse ci-dessous ne fonctionne que pour la version en mode Org antérieure à 9.2

Oui, vous pouvez y ajouter une entrée comme ceci:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Ensuite, dans le fichier org, vous tapez <pet TAB, il se développera en propriété et laissera le point à la position de ?.

Et vous pouvez trouver plus de détails dans la documentation de la variable en tapant C-h v org-structure-template-alist RET.

La fréquence à laquelle ils introduisent des changements incompatibles dans la personnalisation du mode org est vraiment dommage.

Le code suivant vous donne les anciens modèles de structure de org-mode avant la version 9.2. La fonction org-complete-expand-structure-templateest une copie pure de la version 9.1 et org-try-structure-completionest une version légèrement modifiée de celle de 9.1. (J'y ai ajouté une vérification de type.)

Après avoir installé ce code, vous pouvez simplement réutiliser votre ancien modèle
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
.

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))