comment obtenir des tampons (pas seulement des fichiers) pour honorer la liste des modes automatiques?

Q: comment puis-je obtenir de nouveaux tampons pour honorer le mappage auto-mode-alist?

Lors de la recherche d'un fichier , Emacs compare l'extension du fichier à auto-mode-alistpour déterminer le mode principal à utiliser pour le tampon du fichier. Existe-t-il un moyen d'utiliser les informations dans auto-mode-alistpour déterminer le mode d'un tampon auquel aucun fichier n'est (encore) associé?

C'est-à-dire: si j'ouvre un nouveau tampon dont le nom a quelque chose qui ressemble à une extension de fichier, puis-je le faire s'ouvrir automatiquement dans le mode attendu? Par exemple, si je devais ouvrir un nouveau tampon a-new-buffer.elqui n'est pas encore associé à un fichier, je veux qu'il s'ouvre emacs-lisp-modeplutôt que dans le mode par défaut.

Commandes de visite de fichiers telles que C-x C-f ne pas créer de fichier à visiter. Ils font ce que vous cherchez.

Ce n'est que si et lorsque vous essayez d' enregistrer le tampon qu'un fichier est créé .

Si vous n'essayez pas d'enregistrer le tampon, aucun fichier n'est créé. Ce que vous voulez, d'après ce que je comprends jusqu'à présent, est de " visiter un fichier " (ce qui signifie vraiment ouvrir un tampon dans le mode approprié).

Si vous utilisez la solution de Juri Linkov depuis des années.

Je crée des tampons temporaires avec quelque chose comme C-x b test.org C-j. Le major-modeest déterminé par l'extension de fichier via auto-mode-alist.

;; http://thread.gmane.org/gmane.emacs.devel/115520/focus=115794
(setq-default major-mode
              (lambda () (if buffer-file-name
                          (fundamental-mode)
                            (let ((buffer-file-name (buffer-name)))
                          (set-auto-mode)))))

Pour tester l'effet, vous pouvez essayer (prog1 (and (switch-to-buffer "my-new.org") major-mode) (kill-buffer "my-new.org")) => org-mode. Dans un nettoyage, emacs -qle test reviendrait fundamental-mode.

J'ai trouvé une manière basée sur des conseils en utilisant des idées qui provenaient des commentaires de @ Drew et de la réponse de @ glucas que j'enregistrerai ici au cas où elles seraient utiles à n'importe qui.

La version courte: utilisez des afterconseils pour demander si le tampon a un nom de fichier associé, définissez-en un temporairement si ce n'est pas le cas, puis laissez le reste de la set-auto-modemachine s'occuper des détails. Après un peu de test (pas extensif), cela semble très bien fonctionner.

Pour ido-switch-bufferet vanille switch-to-buffer, les deux conseils seraient:

(defadvice ido-switch-buffer (after set-mode activate)
  (unless buffer-file-name
    (let ((buffer-file-name (buffer-name)))
      (set-auto-mode t))))

(defadvice switch-to-buffer (after set-mode activate)
  (unless buffer-file-name
    (let ((buffer-file-name (buffer-name)))
      (set-auto-mode t))))

Je trouve cette option utile en plus du find-filepoint soulevé par @Drew parce que mes doigts peuvent devancer mon cerveau: la mémoire musculaire m'amènera souvent dans un territoire de basculement vers le tampon avant qu'elle ne me vienne à l'esprit qui find-fileferait ce dont j'ai besoin. Maintenant, les deux options sont disponibles.

MISE À JOUR: petit bug potentiellement irritant dans le code ci-dessus: il réexécutera le hook de mode sur le tampon à chaque fois que vous y basculerez. Ce qui suit lui donne un nom de fichier réel hors du /tmprépertoire et évite ce problème:

(defadvice ido-switch-buffer (after set-mode activate)
  (unless buffer-file-name
    (setq buffer-file-name (concat "/tmp/" (buffer-name)))
    (set-auto-mode t)))

La set-auto-modefonction définit le mode en fonction du fichier associé à un tampon. Voici une fonction qui définit temporairement à buffer-file-namepartir du nom du tampon afin de définir le mode:

(defun my/set-buffer-mode (buffer &optional again)
  "Set the mode for BUFFER from the name.  
When called repeatedly for the same buffer only set the mode the first
time, unless the optional argument AGAIN is specified.
Does nothing if the buffer is associated with a file."

  (with-current-buffer buffer
    (when again (kill-local-variable 'my/buffer-mode-set))
    (unless (or buffer-file-name 
            (local-variable-p 'my/buffer-mode-set))
      (let ((buffer-file-name (buffer-name)))
        (set-auto-mode t)
        (setq-local my/buffer-mode-set t)))))

Vous pouvez l'exécuter lorsqu'un tampon est renommé à l'aide des conseils:

(defadvice rename-buffer (after my/rename-update-mode activate)
  (my/set-buffer-mode (current-buffer) 'again))

Je ne suis pas sûr du meilleur endroit pour connecter ceci pour affecter de nouveaux tampons. Ici, j'utilise le buffer-list-update-hook, mais qui est appelé dans plus de cas que nécessaire.

(add-hook 'buffer-list-update-hook
      '(lambda ()
         (my/set-buffer-mode (car (buffer-list)))))

Vous pouvez utiliser des tampons * scratch * dans le but de créer des tampons temporaires qui ont le même mode principal que le fichier sur lequel vous travaillez.

Voici une réponse emacs SE qui pourrait résoudre votre problème:

Comment basculer rapidement entre un fichier et un tampon * scratch * ayant le même mode majeur?

La question et la réponse référencées ont toutes deux été publiées par moi. La réponse dans la fonction fait ce qui suit:

• Si vous travaillez en mode majeur X dans un fichier, l'appel de cette fonction crée un nouveau tampon de travail appelé *scratch-X-mode*s'il n'en existe pas déjà, et bascule vers ce nouveau tampon créé.
• S'il *scratch-X-mode*existe déjà, il passe simplement à ce tampon.
• Le fait d'appeler à nouveau cette fonction dans ce tampon de travail vous ramènera au tampon de fichier sur lequel vous travailliez à l'origine.

Il y a de bonnes réponses ici, mais je voulais ajouter une chose. Emacs a une tonne de fonctionnalités et il y a souvent plusieurs façons de faire quelque chose. Vous pouvez ajouter des balises en haut de n'importe quel fichier qui indiquent à emacs de quel type il s'agit, quelle que soit l'extension. Par exemple, en ajoutant ceci:

# -*-Python-*-

En haut d'un fichier, emacs saura qu'il s'agit d'un fichier Python même sans l' .pyextension. Notez que le #début de la ligne est un commentaire de style Python. Pour différents types de fichiers, vous pouvez utiliser différents commentaires. Par exemple, pour spécifier un fichier Lisp que vous utilisez ;pour démarrer une ligne de commentaire et définir le mode dans emacs comme ceci:

; -*- mode: Lisp;-*-

Voir Spécification des variables de fichier et choix des modes de fichier .