Comment puis-je prévisualiser les formules TeX en ligne dans des modes arbitraires?

Comment puis-je obtenir des aperçus TeX dans des modes autres que AUCTeX ou org-mode? J'aimerais voir les équations TeX en jabber, erc et markdown. Si jamais je passe à Emacs pour le courrier électronique, j'aimerais probablement y voir également des aperçus.

J'ai essayé de réutiliser AUCTeX preview-latex mais j'ai échoué et j'ai abandonné.

Le mode Org offre également la même fonctionnalité . Il s'avère que weechat a réussi à le réutiliser pour afficher automatiquement l'aperçu du latex.

J'ai extrait la partie d'aperçu de weechat dans un fichier séparé que vous pouvez obtenir sur ce dépôt . Il est également disponible en tant que pxpackage sur MELPA (je viens de le soumettre).

Il existe 4 points d'entrée qui peuvent être appelés de manière interactive:

• px-preview: rend tous les fragments de latex dans le tampon courant.
• px-preview-region: restitue des fragments dans la région.
• px-remove: supprime tous les aperçus du tampon actuel (restaurez le texte).
• px-toggle: bascule l'affichage des aperçus dans le tampon courant.

Tant que l'aperçu en mode org fonctionne, celui-ci devrait.

Étant donné que le code est encore assez petit, je vais l'inclure ci-dessous, mais veuillez installer le package ou utiliser le dépôt.

;;; px.el --- preview inline latex -*- lexical-binding: t -*-

;; Most of this code comes from weechat-latex.el which in turn uses
;; org-mode previewer.

;; Copyright (C) 2014 Aurélien Aptel <aurelien.aptel@gmail.com>
;; Copyright (C) 2013 Rüdiger Sonderfeld <ruediger@c-plusplus.de>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(require 'org)

(defvar px-temp-file-prefix "px-"
  "Prefix for temporary files.")

(defvar px-temp-directory-prefix "px-"
  "Prefix for temporary directory.")

(defvar px-image-program org-latex-create-formula-image-program
  "Program to convert LaTeX fragments.
See `org-latex-create-formula-image-program'")

(defvar px-temp-dir nil
  "The temporary directory used for preview images.")

(defun px--create-preview (at)
  "Wrapper for `org-format-latex'.
The parameter AT should be nil or in (TYPE . POINT) format.  With TYPE being a
string showing the matched LaTeX statement (e.g., ``$'') and POINT being the
POINT to replace.  If AT is nil replace statements everywhere."
  (org-format-latex px-temp-file-prefix
                    px-temp-dir
                    'overlays
                    "Creating images...%s"
                    at 'forbuffer
                    px-image-program))

(defun px--set-temp-dir ()
  "Set `px-temp-dir' unless it is already set."
  (unless px-temp-dir
    (setq px-temp-dir
          (make-temp-file px-temp-directory-prefix
                          'directory))))

(defun px-preview ()
  "Preview LaTeX fragments."
  (interactive)
  (save-excursion
    (let ((inhibit-read-only t))
      (px--set-temp-dir)
      (org-remove-latex-fragment-image-overlays)
      (px--create-preview nil))))

(defun px-preview-region (beg end)
  "Preview LaTeX fragments in region."
  (interactive "r")
  (let* ((math-regex (assoc "$" org-latex-regexps))
         (regex (nth 1 math-regex))
         (n (nth 2 math-regex))
         matches)
    (save-excursion
      (goto-char beg)
      (while (re-search-forward regex end t)
        (setq matches (cons (cons "$" (match-beginning n)) matches)))
      (let ((inhibit-read-only t))
        (px--set-temp-dir)
        (dolist (i matches)
          (px--create-preview i))))))


(defun px-remove ()
  "Remove LaTeX preview images."
  (interactive)
  (let ((inhibit-read-only t))
    (org-remove-latex-fragment-image-overlays)))

(defun px-is-active? ()
  "Are LaTeX Previews currently displayed?"
  org-latex-fragment-image-overlays)

(defun px-toggle ()
  "Toggle display of LaTeX preview."
  (interactive)
  (if (px-is-active?)
      (px-remove)
    (px-preview)))


(provide 'px)

Il y a aussi texfrag.elce qui sort de la boîte pour les commentaires doxygen dans prog-mode.

Vous pouvez installer à texfrag.elpartir de melpa-stablevia M-x package-install RET texfrag RET.

Exécutez M-x texfrag-mode RETpour activer l'aperçu. Vous obtenez le menu Aperçu avec tous les éléments du package d'aperçu AUCTeX.

Notez que cela texfragfonctionne également pour éditer les sources html, eww et org-mode.