Exécution asynchrone dans org babel

Existe-t-il une bonne personnalisation générale d'org-babel pour une exécution asynchrone? Récemment, je prévois d'utiliser MATLAB via org-babel, mais j'aimerais qu'il soit asynchrone, car certains calculs prennent du temps.

Je ne souhaite pas personnaliser uniquement ob-matlab. C'est parce que je pense que cela devrait être fait au niveau du framework au lieu d'une application. En d'autres termes, une même modification devrait activer la fonction asynchrone pour d'autres extensions de langue, par exemple la langue R.

Quelqu'un at-il une bonne solution? Jusqu'à présent , je l' ai essayé async.el, ainsi que deferred.elde modifier org-babel-execute-safely-maybequi se trouvent dans ob-core.elle moment.

Jusqu'à présent, j'ai découvert que la création d'un nouveau processus Emacs est une solution.

Voici ce que j'ai fait.

1. Ajoutez une fonction pour démarrer un processus emacs externe.

init.el

(defvar my/async-emacs-repl-org-babel-init-file "~/.emacs.d/org-babel-async-init" "File to load on executing async babel evaluation.")

(defun my/async-emacs-repl--start (process-name init-file)
  "Start a new Emacs process as a REPL server."
  (async-shell-command (concat
                        "TERM=vt200 emacs --batch -nw"
                        " --eval '(load \"" init-file "\")'"
                        " --eval '(while t (print (eval (read))))'"
                        )
                       process-name))

(defun my/async-emacs-repl--org-babel--start-server ()
  "Starts an Emacs process for async org-babel execution."
  (my/async-emacs-repl--start "*org-babel-async*" my/async-emacs-repl-org-babel-init-file))

(defun my/async-emacs-repl--org-babel--start-if-not-exists ()
  "Starts an Emacs process if the process does not exist."
  (if (not (get-buffer-process "*org-babel-async*")) (my/async-emacs-repl--org-babel--start-server)))

(defun my/async-emacs-repl--org-babel--execute--build-command (file-name line-number)
  "Build the command for executing `org-babel-execute-src-block'."
  (concat
   "(progn"
   " (find-file \"" file-name "\")"
   " (revert-buffer t t)"
   " (goto-line " (number-to-string line-number) ")"
   " (org-babel-execute-src-block t)"
   " (save-buffer)"
   ")"
   "\n"))

(defun my/async-emacs-repl--org-babel--execute (process-name file-name line-number)
  "Sends the command to the server to run the code-block the cursor is at."
  (process-send-string
   process-name
   (my/async-emacs-repl--org-babel--execute--build-command file-name line-number)))

(defun my/async-emacs-repl-org-babel-do-execute ()
  "Run org babel execution at point."
  (my/async-emacs-repl--org-babel--execute "*org-babel-async*" (buffer-file-name) (line-number-at-pos)))

(defun my/async-emacs-repl-org-babel-execute ()
  "Run by the user. Executes command. Starts buffer if not exists."
  (interactive)
  (save-buffer)
  (my/async-emacs-repl--org-babel--start-if-not-exists)
  (my/async-emacs-repl-org-babel-do-execute))

2. Ajoutez un fichier de configuration à charger dans le nouveau processus emacs.

La fonction ci-dessus démarre emacs dans le --batchmode. Ainsi, l'init.el normal ne sera pas chargé.

Au lieu de cela, nous voulons créer un fichier de configuration plus court (pour charger les chemins et ainsi de suite).

Le chemin d'accès à notre nouveau fichier de configuration est stocké async-emacs-repl-org-babel-init-filedans l'extrait ci-dessus.

org-babel-async-init.el

;; 1
(package-initialize)

;; 2
(setq org-confirm-babel-evaluate nil)

;; 3
(let ((my/org-babel-evaluated-languages
       '(emacs-lisp
         ditaa
         python
         ruby
         C
         matlab
         clojure
         sh
         dot
         plantuml)))
  (org-babel-do-load-languages
   'org-babel-load-languages
   (mapcar (lambda (lang)
             (cons lang t))
           my/org-babel-evaluated-languages)))

Ici nous ...

1. Ajoutez des chemins d'accès aux packages.
2. Dites à org-mode de ne pas demander s'il faut exécuter le bloc de code.
3. Dites à org-babel quelles langues sont nécessaires.

Note de bas de page 1: Sans ce paramètre, l'évaluation échouera avec "No org-babel-execute function for $lang!"

Note de bas de page 2: Bien sûr, vous pouvez charger le fichier init.el normal au lieu de créer un nouveau fichier de configuration, si vous le souhaitez. Pour ce faire, en ajoutant (setq org-babel-async-init-file "~/.emacs.d/init")à votre init.el. Mais je pense que la création d'un fichier de configuration pour cette tâche est plus simple.

3. De plus ...

Ajouter à init.el

;; This will stop the new process buffer from getting focus.
(setq display-buffer-alist (append display-buffer-alist '(("*org-babel-async*" display-buffer-no-window))))

;; This will automatically show the result section.
(global-auto-revert-mode 1)

Ajouter à org-babel-async-init.el

;; This will skip the "Save anyway?" confirmation of automatically saving the file when you also edited the buffer from Emacs while an asynchronous process is running.
(defun advice:verify-visited-file-modtime (orig-func &rest args) t)
(advice-add 'verify-visited-file-modtime :around 'advice:verify-visited-file-modtime)

;; This will skip the "Select coding system" prompt that appears when the result is inserted. This may vary among environments.
(setq coding-system-for-write 'utf-8)

;; This will skip the "changed on disk; really edit the buffer?" checking.
(defun ask-user-about-supersession-threat (fn) "blatantly ignore files that changed on disk")

Ajouter à org-babel-async-init.el (vous n'en aurez peut-être pas besoin. Ce sont pour MATLAB)

;; This will set MATLAB cli path.
(setq-default matlab-shell-command "/Applications/MATLAB_R2016a.app/bin/matlab")
;; The MATLAB cli path can be obtained by running `fullfile(matlabroot, 'bin')` in your MATLAB.

;; This will stop MATLAB from showing the splash (the MATLAB logo) at the beginning.
(setq-default matlab-shell-command-switches '("-nodesktop" "-nosplash"))

Ajoutez à org-babel-async-init.el (vous n'en aurez peut-être pas besoin. Ce sont pour Julia, R et d'autres langues qui utilisent ESS.)

;; This will enable :session header in Julia and other languages that use ESS (Emacs speaks statistics).
(load "/path/to/ess-site")
;; This will suppress ESS from prompting for session directory.
(setq ess-ask-for-ess-directory nil)

4. Utilisation

(Après la configuration ci-dessus.)

1. Déplacez le curseur sur l'extrait de code que vous souhaitez exécuter.
2. Courez M-x my/async-emacs-repl-org-babel-execute(au lieu de faire C-c C-c). Cela lancera un processus Emacs externe en tant que serveur REPL si nécessaire, puis exécutera le bloc source où vous vous trouvez.

Remerciements

J'ai appris l'idée de démarrer un processus emacs pour l'évaluation org-babel de ce post . Je remercie l'auteur.

Commentaires pour la personnalisation

L'idée ici est simple. Organiser un nouveau processus emacs comme REPL pour Elisp, faire find-filele même fichier .org en cours d' édition, goto-lineau même point du curseur, exécutez org-babel-execute-src-block, save-buffer. Arrêtez de quitter jusqu'à ce que l'utilisateur arrête le processus (sinon, les graphiques disparaîtraient immédiatement après leur affichage). On peut naturellement penser à étendre cela en:

• Utiliser le mode org au C-c C-clieu d'exécuter des fonctions à la main / définir un nouveau raccourci clavier (qui peut être réalisé par des conseils).
• Changement de nom de processus conditionnel selon: la variable de session et la langue
• Changement conditionnel des fichiers init en fonction de la langue.

En fait, le succès de cette approche me semble montrer une manière générale de développer des fonctionnalités asynchrones dans Emacs. Créer une couche "commandes", ajouter des scripts pour effectuer des tâches et disposer d'un cadre pour démarrer et réutiliser les processus emacs. Tout comme le framework Symfony de PHP (PHP n'a pas de threads) a des fonctionnalités de commande.

Modifier l'historique

Code refactorisé (2016-04-02). La solution réutilise maintenant un processus Emacs (2016-04-02). La solution est désormais simplifiée et n'a qu'une seule interactivecommande à exécuter (2016-04-02. Ajout de la configuration (2016-04-12).

Pour les références futures et les bibliothèques prêtes à l'emploi. J'accepterai celui-ci pour la réponse car ils sont plus récents.

ob-async

Voici une bibliothèque utilisant async.el https://github.com/linktohack/ob-async

org-babel-eval-in-repl

Mon autre solution (disponible dans melpa): https://github.com/diadochos/org-babel-eval-in-repl