code machine x86-64, 44 octets
(Le même code machine fonctionne également en mode 32 bits.)
La réponse de @Daniel Schepler était un point de départ pour cela, mais cela a au moins une nouvelle idée algorithmique (pas seulement un meilleur golf de la même idée): les codes ASCII pour 'B'( 1000010) et 'X'( 1011000) donnent 16 et 2 après le masquage avec0b0010010 .
Donc, après avoir exclu décimal (premier chiffre non nul) et octal (le caractère après '0'est inférieur à 'B'), nous pouvons simplement définir base = c & 0b0010010et sauter dans la boucle numérique.
Appelable avec x86-64 System V as unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Extraire la valeur de retour EDX de la moitié supérieure du unsigned __int128résultat avec tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
Les blocs modifiés par rapport à la version de Daniel sont (principalement) indentés moins que les autres instructions. La boucle principale a également sa branche conditionnelle en bas. Cela s'est avéré être un changement neutre car aucun des deux chemins ne pouvait tomber dans le haut, et l' dec ecx / loop .Lentryidée d'entrer dans la boucle s'est avérée ne pas être une victoire après avoir traité octal différemment. Mais il a moins d'instructions à l'intérieur de la boucle avec la boucle sous forme idiomatique faire {} tout en structure, donc je l'ai gardée.
Le harnais de test C ++ de Daniel fonctionne inchangé en mode 64 bits avec ce code, qui utilise la même convention d'appel que sa réponse 32 bits.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Démontage, y compris les octets de code machine qui sont la réponse réelle
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
D'autres changements par rapport à la version de Daniel incluent l'enregistrement de l' sub $16, %alintérieur de la boucle numérique, en utilisant plus subau lieu de testdans le cadre de la détection des séparateurs, et des chiffres par rapport aux caractères alphabétiques.
Contrairement à Daniel, chaque personnage ci '0'- dessous est traité comme un séparateur, pas seulement '\''. (Sauf' ' : and $~32, %al/ jnzdans nos deux boucles traite l'espace comme un terminateur, ce qui est peut-être pratique pour tester avec un entier au début d'une ligne.)
Chaque opération qui se modifie %alà l'intérieur de la boucle a un indicateur de consommation de branche défini par le résultat, et chaque branche va (ou tombe) à un emplacement différent.
