Code machine x86-64 (appel système Linux): 78 octets
Synchronisation en boucle spin RDTSC , sys_writeappel système Linux .
x86-64 ne fournit pas un moyen pratique d'interroger la fréquence de "l'horloge de référence" RDTSC au moment de l'exécution. Vous pouvez lire un MSR (et faire un calcul basé sur cela) , mais cela nécessite le mode noyau, ou root + ouverture /dev/cpu/%d/msr, j'ai donc décidé de faire de la fréquence une constante de temps de construction. (Ajustez FREQ_RDTSCsi nécessaire: toute constante 32 bits ne changera pas la taille du code machine)
Notez que les processeurs x86 ont depuis plusieurs années une fréquence RDTSC fixe, il est donc utilisable comme source de temps, pas comme compteur de performances de cycle d'horloge de base, sauf si vous prenez des mesures pour désactiver les changements de fréquence. (Il existe des compteurs de performances réels pour compter les cycles CPU réels.) Habituellement, il coche à la fréquence nominale de l'autocollant, par exemple 4,0 GHz pour mon i7-6700k, indépendamment du turbo ou de l'économie d'énergie. Quoi qu'il en soit, cette temporisation d'attente ne dépend pas de la moyenne de la charge (comme le ferait une boucle de retard calibrée), et n'est pas non plus sensible à l'économie d'énergie du processeur.
Ce code fonctionnera pour tout x86 avec une fréquence de référence inférieure à 2 ^ 32 Hz, soit jusqu'à ~ 4,29 GHz. Au-delà de cela, les 32 bas de l'horodatage se termineraient en 1 seconde, donc je devrais aussi regarder les edx32 bits élevés du résultat.
Résumé :
pousser 00:00:00\nsur la pile. Puis en boucle:
sys_write appel système- Boucle ADC sur les chiffres (en commençant par le dernier) pour incrémenter le temps de 1. Emballage / report traité avec un
cmp/ cmov, le résultat CF fournissant le report pour le chiffre suivant.
rdtsc et enregistrez l'heure de début.- tourner
rdtscjusqu'à ce que le delta soit> = ticks par seconde de la fréquence RDTSC.
Liste NASM:
1 Address ; mov %1, %2 ; use this macro to copy 64-bit registers in 2 bytes (no REX prefix)
2 Machine code %macro MOVE 2
3 bytes push %2
4 pop %1
5 %endmacro
6
7 ; frequency as a build-time constant because there's no easy way detect it without root + system calls, or kernel mode.
8 FREQ_RDTSC equ 4000000000
9 global _start
10 _start:
11 00000000 6A0A push 0xa ; newline
12 00000002 48BB30303A30303A3030 mov rbx, "00:00:00"
13 0000000C 53 push rbx
14 ; rsp points to `00:00:00\n`
20
21 ; rbp = 0 (Linux process startup. push imm8 / pop is as short as LEA for small constants)
22 ; low byte of rbx = '0'
23 .print:
24 ; edx potentially holds garbage (from rdtsc)
25
26 0000000D 8D4501 lea eax, [rbp+1] ; __NR_write = 1
27 00000010 89C7 mov edi, eax ; fd = 1 = stdout
28 MOVE rsi, rsp
28 00000012 54 <1> push %2
28 00000013 5E <1> pop %1
29 00000014 8D5008 lea edx, [rax-1 + 9] ; len = 9 bytes.
30 00000017 0F05 syscall ; sys_write(1, buf, 9)
31
32 ;; increment counter string: least-significant digits are at high addresses (in printing order)
33 00000019 FD std ; so loop backwards from the end, wrapping each digit manually
34 0000001A 488D7E07 lea rdi, [rsi+7]
35 MOVE rsi, rdi
35 0000001E 57 <1> push %2
35 0000001F 5E <1> pop %1
36
37 ;; edx=9 from the system call
38 00000020 83C2FA add edx, -9 + 3 ; edx=3 and set CF (so the low digit of seconds will be incremented by the carry-in)
39 ;stc
40 .string_increment_60: ; do {
41 00000023 66B93902 mov cx, 0x0200 + '9' ; saves 1 byte vs. ecx.
42 ; cl = '9' = wrap limit for manual carry of low digit. ch = 2 = digit counter
43 .digitpair:
44 00000027 AC lodsb
45 00000028 1400 adc al, 0 ; carry-in = cmp from previous iteration; other instructions preserve CF
46 0000002A 38C1 cmp cl, al ; manual carry-out + wrapping at '9' or '5'
47 0000002C 0F42C3 cmovc eax, ebx ; bl = '0'. 1B shorter than JNC over a MOV al, '0'
48 0000002F AA stosb
49
50 00000030 8D49FC lea ecx, [rcx-4] ; '9' -> '5' for the tens digit, so we wrap at 59
51 00000033 FECD dec ch
52 00000035 75F0 jnz .digitpair
53 ; hours wrap from 59 to 00, so the max count is 59:59:59
54
55 00000037 AC lodsb ; skip the ":" separator
56 00000038 AA stosb ; and increment rdi by storing the byte back again. scasb would clobber CF
57
58 00000039 FFCA dec edx
59 0000003B 75E6 jnz .string_increment_60
60
61 ; busy-wait for 1 second. Note that time spent printing isn't counted, so error accumulates with a bias in one direction
62 0000003D 0F31 rdtsc ; looking only at the 32-bit low halves works as long as RDTSC freq < 2^32 = ~4.29GHz
63 0000003F 89C1 mov ecx, eax ; ecx = start
64 .spinwait:
65 ; pause
66 00000041 0F31 rdtsc ; edx:eax = reference cycles since boot
67 00000043 29C8 sub eax, ecx ; delta = now - start. This may wrap, but now we have the delta ready for a normal compare
68 00000045 3D00286BEE cmp eax, FREQ_RDTSC ; } while(delta < counts_per_second)
69 ; cmp eax, 40 ; fast count to test printing
70 0000004A 72F5 jb .spinwait
71
72 0000004C EBBF jmp .print
next address = 0x4E = size = 78 bytes.
Décommentez l' pauseinstruction d'économiser une puissance significative: cela chauffe un cœur de ~ 15 degrés C sans pause, mais seulement de ~ 9 avec pause. (Sur Skylake, où il pausedort pendant ~ 100 cycles au lieu de ~ 5. Je pense que cela économiserait plus s'il rdtscn'était pas aussi lent, donc le CPU ne fait pas beaucoup de temps).
Une version 32 bits serait plus courte de quelques octets, par exemple en utilisant une version 32 bits pour pousser la chaîne initiale 00: 00: 00 \ n.
16 ; mov ebx, "00:0"
17 ; push rbx
18 ; bswap ebx
19 ; mov dword [rsp+4], ebx ; in 32-bit mode, mov-imm / push / bswap / push would be 9 bytes vs. 11
Et en utilisant également 1 octet dec edx. L' int 0x80appel système ABI n'utiliserait pas esi / edi, donc la configuration du registre pour syscall vs lodsb / stosb pourrait être plus simple.
