Comment afficher uniquement des albums complets dans iTunes 11?

iTunes 11 semble tourner autour de l'écran qui vous montre tous les différents albums que vous possédez. Cependant, la grande majorité des albums que iTunes me montre sont des albums dont je ne possède qu'une chanson, et il est difficile de trouver ces albums complets.

Dans iTunes 11, comment filtrez-vous les albums affichés dans le volet Albums?

Il n'y a aucun moyen de le faire, hélas. Cet indice montre un AppleScript capable de créer des listes de lecture pour tous les albums complets, mais si vous avez beaucoup d'albums, cela risque d'être écrasant.

Créez une liste de lecture intelligente avec le filtre suivant - Les commentaires contiennent l'album complet. Pour chaque album que je veux ajouter, je clique sur Obtenir des informations et ajoute l'album complet au champ de commentaires.

Tu ne peux pas. Ecrivez une suggestion à Apple à l' adresse suivante : http://www.apple.com/feedback/itunesapp.html

Vous pouvez créer une liste de lecture contenant tous les albums complets de votre bibliothèque à l'aide de AppleScript. Le code ci-dessous n'est qu'une petite modification du script lié à la réponse de Kirk afin de créer une liste de lecture au lieu d'une par album. C'est lent (cela prend peut-être 5 minutes pour parcourir ma bibliothèque) et il est très sensible aux inexactitudes des métadonnées, mais cela fonctionne pour moi.

-- Creates one playlist of all full albums you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Original script by duozmo on Ask Different
-- http://hints.macworld.com/article.php?story=20130201061128257
-- http://apple.stackexchange.com/a/77626

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set albumPlaylistName to "Full Albums"
    -- Create playlist
    if user playlist albumPlaylistName exists then
        try
            delete tracks of user playlist albumPlaylistName
        end try
    else
        make new user playlist with properties {name:albumPlaylistName}
    end if

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog albumPlaylistName & " playlist created!"
end tell

Une autre option consisterait à utiliser le script Random Full Albums de Doug si vous voulez simplement qu'iTunes agisse comme un changeur de CD en mode de lecture aléatoire des albums.