Voici une solution AppleScript. Cela devrait vous donner une liste complète des fichiers ouverts (y compris le chemin d'accès complet) dans l'application de prévisualisation.
En outre, si un gourou AppleScript trouve cette réponse, je vous serais reconnaissant de toute critique constructive de votre part. :)
set text item delimiters to "\n"
set myList to {}
tell application "Preview"
set theDocs to get documents
repeat with eachDoc in theDocs
set thePath to path of eachDoc
copy thePath to end of myList
end repeat
end tell
set the_list to myList as text
tell application "Finder"
set myFile to "/Users/YourName/YourFolder/FileName.txt"
do shell script "date >> " & myFile
do shell script "echo " & quoted form of the_list & " >> " & myFile
end tell
Ceci imprimera la date actuelle suivie d'une liste de tous les documents ouverts dans Aperçu. Si vous préférez omettre la date, supprimez simplement la ligne:
do shell script "date >> " & myFile
Assurez-vous de renseigner les informations correctes sur la ligne:
set myFile to "/Users/YourName/YourFolder/FileName.txt"
Si vous souhaitez ajouter une date à vos noms de fichiers, il suffit de mettre les lignes suivantes sous le tell application "Finder"bloc
set time_stamp to (do shell script "date \"+%m-%d-%y\"")
set myFile to "/Users/YourName/YourFolder/PreviewProfile_" & time_stamp & ".txt"
La datecommande de terminal a beaucoup de formats différents disponibles. Pour en savoir plus sur les différentes options disponibles, ouvrez votre terminal et tapez man strftime.
Après avoir joué un peu plus, je me rends compte que ce script peut encore être simplifié. Ceci est une version plus simplifiée qui évite certaines étapes inutiles de l'original. Mais le résultat est le même dans les deux cas.
set text item delimiters to "\n"
tell application "Preview"
set theDocs to get path of every document as text
tell application "Finder"
set time_stamp to (do shell script "date \"+%m-%d-%y\"")
set myFile to "/Users/YourName/YourFolder/PreviewProfile_" & time_stamp & ".txt"
do shell script "echo " & quoted form of theDocs & " >> " & myFile
end tell
end tell
Pour faciliter l'utilisation, vous pouvez enregistrer ce script en tant que service Automator à utiliser lorsque vous travaillez dans une application. Pour ce faire, ouvrez simplement Automator - dans le menu Fichier , sélectionnez Nouveau ou ⌘N à partir du clavier. Ensuite, sélectionnez Service parmi les choix indiqués. Lorsque le document s'ouvre, sélectionnez Utilitaires dans la colonne de gauche. Sélectionnez ensuite Exécuter AppleScript dans la colonne à droite de celle-ci. Collez ce script dans la zone qui apparaît. Dans les choix déroulants situés en haut de la page, sélectionnez Le service ne reçoit aucune entrée et dans n’importe quelle application.. Ensuite, il vous suffit de choisir un nom, de sauvegarder le fichier et de disposer d’un service disponible à tout moment dans le menu Services.
Mettre à jour
Voici un moyen de lire et d’ouvrir la liste des fichiers que nous venons de créer. Cela vous permettra de choisir les fichiers que vous souhaitez ouvrir sans avoir à ouvrir tous les fichiers de la liste si vous ne le souhaitez pas.
tell application "Finder"
set file_list to {}
set my_files to paragraphs of (read "/Users/YourName/path/to/YourFile")
repeat with nextLine in my_files
if length of nextLine is greater than 0 then
copy nextLine to the end of file_list
end if
end repeat
choose from list file_list with multiple selections allowed
set chosen_Files to the result
repeat with next_file in chosen_Files
do shell script "open " & next_file
end repeat
end tell
J'espère que ça aide. Dites moi si vous avez le moindre problème.