Comment créer une boîte de dialogue multi-champs dans AppleScript (pour demander l'heure à l'utilisateur)?

J'ai une application Automator que je voudrais demander à l'utilisateur d'entrer une heure de son choix.

Idéalement, j'aimerais que la boîte de dialogue comporte trois champs:

1) champ d'heure

2) Champ minutes

3) Période (pm ou am)

Les champs un et deux sont saisissables par l'utilisateur et il y a un signe deux-points entre les deux champs. Le champ trois est une simple liste déroulante et l'utilisateur doit sélectionner l'une des deux options.

Je voudrais également que AppleScript vérifie que le texte saisi dans les champs heure et minute est conforme aux normes de temps; s'il ne le fait pas, un message d'erreur s'affiche et l'utilisateur doit à nouveau saisir le texte. (Par exemple, le texte entré dans le premier champ doit être un nombre à un chiffre compris entre 1 et 12 et le texte entré dans le deuxième champ doit être un nombre à deux chiffres compris entre 00 et 60.)

Je sais que tout cela peut être accompli dans trois boîtes de dialogue distinctes, mais je préférerais vraiment que tout soit complété dans une seule boîte de dialogue (afin de présenter à l'utilisateur une interface utilisateur pratique).

Je ne suis pas très compétent en AppleScript, ce projet est donc extrêmement ambitieux pour moi. Cela peut-il être accompli dans AppleScript?

Si ce comportement n'est pas possible AppleScript, quelqu'un peut-il recommander un autre langage similaire dans lequel ce type de boîte de dialogue est possible?

Je vous remercie.

Cela ne peut pas être fait dans AppleScript.

Cependant, j'ai trouvé cette solution de contournement : le texte saisi sur chaque ligne d'un champ est interprété comme une réponse distincte:

-- multiple input dialog

on run -- example
    set {firstName, lastName} to (inputItems for {"• First Name", "• Last Name"} with title given prompt:"Enter the following items separated by a carriage return:")
    display dialog "First Name:  \"" & firstName & "\"" & return & "Last Name:  \"" & lastName & "\""
end run

to inputItems for someItems given title:theTitle, prompt:thePrompt
    (*
    displays a dialog for multiple item entry - a carriage return is used between each input item
    for each item in someItems, a line of text is displayed in the dialog and a line is reserved for the input
        the number of items returned are padded or truncated to match the number of items in someItems
    to fit the size of the dialog, items should be limited in length (~30) and number (~15)  
        parameters -        someItems [list/integer]: a list or count of items to get from the dialog
                        theTitle [boolean/text]: use a default or the given dialog title
                        thePrompt [boolean/text]: use a default or the given prompt text
        returns [list]:     a list of the input items
    *)
    if thePrompt is in {true, false} then -- "with" or "without" prompt
        if thePrompt then
            set thePrompt to "Input the following items:" & return & return -- default
        else
            set thePrompt to ""
        end if
    else -- fix up the prompt a bit
        set thePrompt to thePrompt & return & return
    end if

    if theTitle is in {true, false} then if theTitle then -- "with" or "without" title
        set theTitle to "Multiple Input Dialog" -- default
    else
        set theTitle to ""
    end if

    if class of someItems is integer then -- no item list
        set {theCount, someItems} to {someItems, ""}
        if thePrompt is not "" then set thePrompt to text 1 thru -2 of thePrompt
    else
        set theCount to (count someItems)
    end if
    if theCount is less than 1 then error "inputItems handler:  empty input list"
    set {theItems, theInput} to {{}, {}}

    repeat theCount times -- set the number of lines in the input
        set the end of theInput to ""
    end repeat
    set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
    set {someItems, theInput} to {someItems as text, theInput as text}
    set AppleScript's text item delimiters to tempTID

    set theInput to paragraphs of text returned of (display dialog thePrompt & someItems with title theTitle default answer theInput)

    repeat with anItem from 1 to theCount -- pad/truncate entered items
        try
            set the end of theItems to (item anItem of theInput)
        on error
            set the end of theItems to ""
        end try
    end repeat
    return theItems
end inputItems