Créer un nouveau fichier (.txt) dans le Finder - Raccourci clavier

Je voulais savoir s'il existe un moyen de définir des raccourcis clavier pour créer de nouveaux fichiers dans le Finder. Par exemple, par défaut, vous pouvez créer un nouveau dossier à l'aide de CMD+ Shift+ N. Existe-t-il un raccourci clavier pour créer un nouveau fichier texte? Je suis programmeur donc ce serait extrêmement utile

Je serais également intéressé à créer un autre type de fichier à l'aide de raccourcis clavier.

J'ai essayé d'utiliser l'automate, mais je trouve cela assez déroutant et je ne sais pas comment j'y connecterais un raccourci clavier.

Eh bien, c'est parti avec un AppleScript pour ça.

Tout d'abord, créez l'AppleScript:

1. Ouvrez Automator
2. Créer une action rapide
3. Réglez l'entrée sur aucune entrée
4. Faites glisser et déposez l' élément de flux de travail Exécuter AppleScript sur l'espace gris.
5. Collez le code ci-dessous dans l'AppleScript
6. Enregistrez le flux de travail sous Créer un nouveau fichier
   Si vous avez activé iCloud Drive, assurez-vous que vous enregistrez le fichier sous Library/Services/dans votre dossier personnel.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

Pour l'ajouter comme raccourci:

• Allez dans Préférences Système -> Clavier -> Raccourcis -> Services
• Faites défiler vers le bas jusqu'à ce que vous trouviez le service Créer un nouveau fichier
• Attribuez-lui un raccourci en cliquant sur le côté droit aucun , qui se transforme en a Add Shortcut.
  Cliquez sur le bouton et saisissez le raccourci que vous souhaitez utiliser.
  J'utilise ⌘ Command+ ⌥ Option+N

J'ai créé un AppleScript très similaire à celui de @ YoshiBotX, mais avec quelques améliorations.

L'idée est de créer un workflow Automator et de lui attribuer un raccourci en procédant comme suit:

• Ouvrez Automator et créez un service ;
• Définissez l'entrée sur aucune entrée et l'application sur Finder.app ;
• Faites glisser et déposez l' élément de flux de travail Exécuter AppleScript sur l'espace gris;
• Mettez le contenu de cet AppleScript dans la zone de texte;
• Enregistrez le flux de travail avec un nom raisonnable (comme un nouveau fichier );
• Accédez à Paramètres -> Clavier -> Raccourcis -> Services et attribuez-lui un raccourci.

Maintenant, montrons l'AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Pour plus de commodité, je mets cet AppleScript dans ce GitHub Gist .

Vous pouvez créer un service Automator vous-même - c'est assez simple à faire. Ensuite, vous pouvez lui attribuer un raccourci clavier afin que vous n'ayez pas besoin d'activer le service via le menu des services (ce que vous pouvez faire de toute façon).

Ouvrez Automator et sélectionnez Service comme type de nouveau document.

Définissez le service pour qu'il ne reçoive aucune entrée dans Finder.app et ajoutez l'action Nouveau document TextEdit au flux de travail.

Enregistrez le service, puis ouvrez Préférences Système → Clavier → Raccourcis → Services où vous trouverez le service répertorié sous Général avec le nom que vous avez donné pour le service lorsque vous l'avez enregistré.

Ajoutez un raccourci clavier au service en sélectionnant le service puis en cliquant sur «ajouter un raccourci».

Ici, vous pourriez avoir quelques problèmes si le raccourci est déjà utilisé. Soyez donc créatif pour en créer un qui fonctionne pour vous.

Vous pouvez également attribuer un raccourci à un script comme celui-ci:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

L'emplacement d'insertion est la cible de la fenêtre du Finder la plus en avant ou du bureau.

terminal ouvert et type

touch filename

ou

> filename

Ceci est une rediffusion d'un post que j'ai fait l'année dernière. J'ai eu une bonne expérience avec ce qui suit.

Vous pouvez télécharger et installer deux utilitaires utiles qui vous permettront de créer un nouveau fichier texte (ou fichier RTF) dans un dossier actuellement ouvert que vous consultez à l'aide du Finder.

Les utilitaires sont appelés NewTextFileHere et NewRTFHere et peuvent être téléchargés depuis

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

Les icônes de l'une de ces applications peuvent ensuite être incluses dans toutes vos fenêtres du Finder.

Exactement ce que je cherchais, Richard Fuhr. Merci pour cela.

Une remarque: le lien de cette URL pour le NewTextFileHere semble se charger sur une page vide. Mais j'ai fait une recherche et trouvé l'application ici: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Une alternative, si vous avez déjà BetterTouchTools (c'était une application gratuite, maintenant elle a un modèle payez ce que vous voulez avec une période d'essai de 30 jours), vous pouvez trouver l'action sur "Utility Actions > Create New File in Current Folder"laquelle fait exactement cela, avec un pop-up pour vous permettre de choisir le nom. Attribuez le raccourci que vous souhaitez (j'ai choisi Option + Maj + N) et vous êtes prêt à partir.

Dans le cas où vous utilisez MacVim, il existe une option sous Finder -> Servicespour créer un nouveau tampon vim:

Je cartographié au raccourci ShiftcmdMdans System Preferences -> Keyboard -> Shortcuts: