Positionnement des icônes du bureau à gauche au lieu de droite

N'importe quel moyen de créer automatiquement un alias ou des icônes sur le côté gauche du bureau Apple. Par défaut, ils vont vers la droite.

Il n'y a aucun moyen de forcer les icônes à aller automatiquement à gauche (et à rester organisé selon le critère que vous choisissez).

Pour résoudre ce problème, vous pouvez modifier les options d'affichage dans le Finder pour ne pas organiser les éléments en fonction de n'importe quel critère et placer les icônes manuellement sur la gauche.

• Cliquez sur un espace vide sur le bureau.
• Appuyez sur Cmd+ Jou utilisez la souris pour accéder au menu Affichage du Finder > Afficher les options d' affichage.
• Dans la liste déroulante Trier par: dans la boîte de dialogue, choisissez Aucun ou Accrocher à la grille .
• Vous pourrez déposer des fichiers n'importe où sur votre bureau et ils y resteront.

Voir Notions de base sur Mac: modifiez vos fenêtres pour plus d'informations.

Parcourez également les pages Mac Basics pour en savoir plus sur l'utilisation d'un Mac.

Ce n'est pas la meilleure solution mais cela peut fonctionner si rien d'autre ne le fait ...

1. Créez une action de dossier Automator associée au bureau.
2. Ajouter l'élément: "exécuter applescript"

3. Collez le code suivant dans la zone de texte applescript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Ainsi, chaque fois qu'un fichier est ajouté à votre bureau, tous les fichiers seront réorganisés par ordre alphabétique ...

Organisez tous les dossiers dans l'ordre que vous souhaitez. Ensuite, sous Affichage, cliquez sur «nettoyer». Cela alignera tout bien. Ensuite, vous pouvez simplement mettre en surbrillance tous les dossiers et les positionner exactement où vous le souhaitez. Les Mac n'organisent pas les dossiers sur la gauche, seulement sur la droite, mais en quelques étapes faciles, vous pouvez tout organiser proprement sur la gauche.

Je viens de mettre en surbrillance tous les dossiers du côté droit, puis de les saisir tous et de les coller à gauche.